File Coverage

blib/lib/Geography/Countries.pm

Criterion	Covered	Total	%
statement	62	65	95.3
branch	14	18	77.7
condition	2	2	100.0
subroutine	18	21	85.7
pod	5	6	83.3
total	101	112	90.1

package Geography::Countries;

use 5.006;

use strict;
use warnings;
no  warnings 'syntax';

use Exporter ();

our @ISA         = qw /Exporter/;
our @EXPORT      = qw /country/;
our @EXPORT_OK   = qw /code2         code3       numcode       countries
                       CNT_I_CODE2   CNT_I_CODE3 CNT_I_NUMCODE CNT_I_COUNTRY
                       CNT_I_FLAG
                       CNT_F_REGULAR CNT_F_OLD   CNT_F_REGION  CNT_F_ANY/;
our %EXPORT_TAGS = (LISTS   => [qw /code2 code3   numcode     countries/],
                    INDICES => [qw /CNT_I_CODE2   CNT_I_CODE3 CNT_I_NUMCODE
                                    CNT_I_COUNTRY CNT_I_FLAG/],
                    FLAGS   => [qw /CNT_F_REGULAR CNT_F_OLD
                                    CNT_F_REGION  CNT_F_ANY/],);

our $VERSION     = '2009041301';


use constant CNT_I_CODE2   =>    0;
use constant CNT_I_CODE3   =>    1;
use constant CNT_I_NUMCODE =>    2;
use constant CNT_I_COUNTRY =>    3;
use constant CNT_I_FLAG    =>    4;

use constant CNT_F_REGULAR => 0x01;
use constant CNT_F_OLD     => 0x02;
use constant CNT_F_REGION  => 0x04;
use constant CNT_F_ANY     => CNT_F_REGULAR | CNT_F_OLD | CNT_F_REGION;

my (%info, @code2, @code3, @numcode, @countries);

sub norm ($) {
    my $query = shift;
    die "Illegal argument to norm\n" unless defined $query;
    return sprintf "%03d" => $query  unless $query =~ /\D/;
    $query =  lc $query;
    $query =~ s/\s+//g;

    $query;
}

binmode (DATA, ':encoding(iso-8859-1)') if $] >= 5.008;

my $flag;
my %flags   = (
    Regular => CNT_F_REGULAR,
    Old     => CNT_F_OLD,
    Region  => CNT_F_REGION,
);
while () {
    chomp;
    last if $_ eq '__END__';
    s/#.*//;
    next unless /\S/;
    if (/^%%\s*(\S.*\S)\s*%%$/) {
        $flag = $flags {$1} or
                 die "Found illegal flag ``$1'' while parsing __DATA__\n";
        next;
    }
    my $code2   = substr $_,  0, 2;  $code2   = undef if $code2   =~ /\s/;
    my $code3   = substr $_,  3, 3;  $code3   = undef if $code3   =~ /\s/;
    my $numcode = substr $_,  7, 3;  $numcode = undef if $numcode =~ /\s/;
    my $country = substr $_, 11;

    push @code2     =>  $code2   if defined $code2;
    push @code3     =>  $code3   if defined $code3;
    push @numcode   =>  $numcode if defined $numcode;
    push @countries =>  $country;

    my $info    = [$code2, $code3, $numcode, $country, $flag];

    $info {norm $code2}   =  $info if defined $code2  ;
    $info {norm $code3}   =  $info if defined $code3  ;
    $info {$numcode}      =  $info if defined $numcode;

    $info {norm $country} =  $info;
}

@code2     = sort @code2;
@code3     = sort @code3;
@numcode   = sort @numcode;
@countries = sort @countries;

sub code2     {@code2}
sub code3     {@code3}
sub numcode   {@numcode}
sub countries {@countries}


sub country ($;$) {
    my $sub = (caller (0)) [3];

    die "No arguments for $sub.\n"           unless @_;
    die "Too many arguments for $sub.\n"     unless @_ <= 2;

    my ($query, $flags) = @_;

    die "Undefined argument for $sub.\n"     unless defined $query;

    $flags ||=  CNT_F_REGULAR;

    die "Illegal second argument to $sub.\n" if $flags =~ /\D/;

    my $info =  $info {norm $query} or return;

    return unless $info -> [CNT_I_FLAG] & $flags;

    wantarray ? @$info : $info -> [CNT_I_COUNTRY];

}

1;

=pod

=head1 NAME

Geography::Countries - 2-letter, 3-letter, and numerical codes for countries.

=head1 SYNOPSIS

    use Geography::Countries;

    $country = country 'DE';  # 'Germany'
    @list    = country  666;  # ('PM', 'SPM', 666,
                              #  'Saint Pierre and Miquelon', 1)

=head1 DESCRIPTION

This module maps country names, and their 2-letter, 3-letter and
numerical codes, as defined by the ISO-3166 maintenance agency [1],
and defined by the UNSD.

=head2 The C subroutine.

This subroutine is exported by default. It takes a 2-letter, 3-letter or
numerical code, or a country name as argument. In scalar context, it will
return the country name, in list context, it will return a list consisting
of the 2-letter code, the 3-letter code, the numerical code, the country
name, and a flag, which is explained below. Note that not all countries
have all 3 codes; if a code is unknown, the undefined value is returned.

There are 3 categories of countries. The largest category are the
current countries. Then there is a small set of countries that no
longer exist. The final set consists of areas consisting of multiple
countries, like I. No 2-letter or 3-letter codes are available
for the second two sets. (ISO 3166-3 [3] defines 4 letter codes for the
set of countries that no longer exist, but the author of this module
was unable to get her hands on that standard.) By default, C
only returns countries from the first set, but this can be changed
by giving C an optional second argument.

The module optionally exports the constants C,
C, C and C. These constants can also
be important all at once by using the tag C<:FLAGS>. C is just
the binary or of the three other flags. The second argument of C
should be the binary or of a subset of the flags C,
C, and C - if no, or a false, second argument is
given, C is assumed. If C is set, regular
(current) countries will be returned; if C is set, old,
no longer existing, countries will be returned, while C
is used in case a region (not necessarely) a country might be returned.
If C is used in list context, the fifth returned element is
one of C, C and C, indicating
whether the result is a regular country, an old country, or a region.

In list context, C returns a 5 element list. To avoid having
to remember which element is in which index, the constants C,
C, C, C and C
can be imported. Those constants contain the indices of the 2-letter code,
the 3-letter code, the numerical code, the country, and the flag explained
above, respectively. All index constants can be imported by using the
C<:INDICES> tag.

=head2 The C, C, C and C routines.

All known 2-letter codes, 3-letter codes, numerical codes and country
names can be returned by the routines C, C, C and
C. None of these methods is exported by default; all need to
be imported if one wants to use them. The tag C<:LISTS> imports them
all. In scalar context, the number of known codes or countries is returned.

=head1 REFERENCES

The 2-letter codes come from the ISO 3166-1:1997 standard [2]. ISO 3166
bases its list of country names on the list of names published by
the United Nations. This list is published by the Statistical Division
of the United Nations [4]. The UNSD uses 3-letter codes, and numerical
codes [5]. The information about old countries [6] and regions [7] also
comes from the United Nations.

In a few cases, there was a conflict between the way how the United
Nations spelled a name, and how ISO 3166 spells it. In most cases,
is was word order (for instance whether I should
preceed the name, or come after the name. A few cases had minor
spelling variations. In all such cases, the method in which the UN
spelled the name was choosen; ISO 3166 claims to take the names from
the UN, so we consider the UN authoritative.

=over 4

=item [1]

ISO Maintenance Agency (ISO 3166/MA)
I.

=item [2]

I,
I,
7 September 1999.

=item [3]

ISO 3166-3, I.
I.

=item [4]

United Nations, Statistics Division.
I.

=item [5]

I.
I,
26 August 1999.

=item [6]

I.
I,
26 August 1999.

=item [7]

I.
I,
26 August 1999.

=back

=head1 BUGS

Looking up information using country names is far from perfect.
Except for case and the amount of white space, the exact name as it
appears on the list has to be given. I will not return anything,
but I will.

=head1 DEVELOPMENT

The current sources of this module are found on github,
L<< git://github.com/Abigail/geography--countries.git >>.

=head1 AUTHOR

Abigail L<< mailto:[e-mail] >>.

=head1 COPYRIGHT and LICENSE

Copyright (C) 1999, 2009 by Abigail

Permission is hereby granted, free of charge, to any person obtaining a
copy of this software and associated documentation files (the "Software"),
to deal in the Software without restriction, including without limitation
the rights to use, copy, modify, merge, publish, distribute, sublicense,
and/or sell copies of the Software, and to permit persons to whom the
Software is furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included
in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
THE AUTHOR BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT
OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.

=cut

__DATA__