File Coverage

blib/lib/Finance/Bank/Wachovia.pm

Criterion	Covered	Total	%
statement	79	80	98.7
branch	13	18	72.2
condition	8	15	53.3
subroutine	22	23	95.6
pod	5	5	100.0
total	127	141	90.0

package Finance::Bank::Wachovia;

use Finance::Bank::Wachovia::ErrorHandler;
use Finance::Bank::Wachovia::Account;
use Finance::Bank::Wachovia::Credit;
use Finance::Bank::Wachovia::Transaction;
use Finance::Bank::Wachovia::DataObtainer::WWW;
use strict;
use warnings;

our $VERSION = '0.3';
my @attrs;
our @ISA = qw/Finance::Bank::Wachovia::ErrorHandler/;

BEGIN{
	@attrs = qw(
		customer_access_number
		pin
		code_word
		user_id
		password
		accounts
		data_obtainer
	);

	my $x = @__SUPER__::ATTRIBUTES;
	for( @attrs ){
		eval "sub _$_ { $x }";
		$x++;
	}
}

sub new {
	my($class, %attrs) = @_;
	my $self = [];
	bless $self, $class;
	foreach my $att ( keys %attrs ){
		$self->$att( $attrs{$att} );
	}
	unless( ( $self->user_id && $self->password ) || ( $self->customer_access_number && $self->pin && $self->code_word ) ){
		return Finance::Bank::Wachovia->Error( "Must use either user_id/password OR customer_access_number/pin/code_word" );
	}
	my %login_info = ( $self->user_id && $self->password )
					? ( user_id => $self->user_id, password => $self->password )
					: ( 	customer_access_number => $self->customer_access_number, pin => $self->pin, code_word => $self->code_word	);
	my $data_obtainer = Finance::Bank::Wachovia::DataObtainer::WWW->new(
		%login_info
	);
	$self->data_obtainer( $data_obtainer );
	$self->accounts({});
	return $self;
}


sub AUTOLOAD {
	no strict 'refs';
	our $AUTOLOAD;
	my $self = shift;
	my $attr = lc $AUTOLOAD;
	$attr =~ s/.*:://;
	return $self->Error("$attr not a valid attribute")
		unless grep /$attr/, @attrs;
	# get if no args passed
	return $self->[ &{"_$attr"} ] unless @_;
	# set if args passed
	$self->[ &{"_$attr"} ] = shift;
	return $self;
}

sub account_numbers {
	my $self = shift;
	my $do = $self->data_obtainer();
	return $do->get_account_numbers();
}

sub account_names {
	my $self = shift;
	my $do = $self->data_obtainer();
	return map { $do->get_account_name($_) } $self->account_numbers();
}

sub account_balances {
	my $self = shift;
	my $do = $self->data_obtainer();
	return map { $do->get_account_available_balance($_) } $self->account_numbers();
}

sub account {
	my($self, $account_number) = @_;
	if( exists $self->accounts->{$account_number} ){
		return $self->accounts->{$account_number};
	}
	return $self->Error("must pass valid account number to account(), got '$account_number'")
		unless $account_number =~ /^\d+$/;
	my $do = $self->data_obtainer();
	my $account;
	#note: we don't set posted_balance here, since that requires extra
	# work by the obtainer, we defer the retrieval of that until it's
	# needed (asked for via $account->posted_balance)
	if( $account_number =~ /\d{16}/ ){ # must be credit?
			$account = Finance::Bank::Wachovia::Credit->new(
				number			=> $account_number,
				data_obtainer	=> $do,
			)
			or return Error( "Couldn't create Credit object: ".Finance::Bank::Wachovia::Credit->ErrStr );

	}
	else{ # must be checkings or savings?
			$account = Finance::Bank::Wachovia::Account->new(
				number			=> $account_number,
				data_obtainer	=> $do,
			)
			or return Error( "Couldn't create Account object: ".Finance::Bank::Wachovia::Account->ErrStr );
	}
	$self->accounts->{$account_number} = $account;
	return $account;
}

sub DESTROY {}

__END__