File Coverage

lib/Finance/Bank/DE/NetBank.pm

Criterion	Covered	Total	%
statement	28	152	18.4
branch	0	46	0.0
condition	2	42	4.7
subroutine	8	15	53.3
pod	8	8	100.0
total	46	263	17.4

package Finance::Bank::DE::NetBank;

use strict;
use vars qw($VERSION $DEBUG);
use base qw(Class::Accessor);
Finance::Bank::DE::NetBank->mk_accessors(
    qw(BASE_URL BLZ CUSTOMER_ID PASSWORD AGENT_TYPE AGENT ACCOUNT Debug));

use WWW::Mechanize;
use Text::CSV_XS;
use Data::Dumper;

$| = 1;

$VERSION = "1.05_01";

sub Version {
    return $VERSION;
}

sub new {
    my $proto  = shift;
    my %values = (
        AGENT_TYPE => "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1) ",
        BASE_URL =>
          'https://www.netbank-money.de/netbank-barrierefrei-banking/view/',
        BLZ         => '20090500', # NetBank BLZ
        CUSTOMER_ID => '',
        PASSWORD    => '',
        ACCOUNT     => '',
        @_
    );

    my $class = ref($proto) || $proto;
    my $parent = ref($proto) && $proto;

    my $self = {};
    bless( $self, $class );

    foreach my $key ( keys %values ) {
        $self->$key("$values{$key}");
    }

    return $self;
}

sub connect {
    my $self  = shift;
    print STDERR "Method connect() is deprecated. Use only login() instead!\n";
    return $self->login(@_);
}

sub login {
    my $self   = shift;
    my %values = (
        CUSTOMER_ID => $self->CUSTOMER_ID(),
        PASSWORD    => $self->PASSWORD(),
        @_
    );

    my $url   = $self->BASE_URL() . "index.jsp?blz=" . $self->BLZ();
    my $agent = WWW::Mechanize->new( agent => $self->AGENT_TYPE(), );
    $agent->get($url);
    $self->AGENT($agent);

    $agent->field( "kundennummer", $values{'CUSTOMER_ID'} );
    $agent->field( "pin",          $values{'PASSWORD'} );
    $agent->click();

    print STDERR Dumper( $agent->content ) if $self->Debug();

    if ($agent->content =~ /fieldtableerrorred/ig) {
        return undef;
    }

    return 1;

}

sub saldo {
    my $self = shift;
    my $data = $self->statement(@_);

    if ($data) {
        print STDERR Dumper($data) if $self->Debug();
        return $data->{'STATEMENT'}{'SALDO'};
    } else {
        return undef;
    }
}

sub statement {
    my $self   = shift;
    my %values = (
        TIMEFRAME => "30"
        , # 1 or 30 days || "alle" = ALL || "variabel" = between START_DATE and END_DATE only
        START_DATE => 0,                  # dd.mm.yyyy
        END_DATE   => 0,                  # dd.mm.yyyy
        ACCOUNT    => $self->ACCOUNT(),
        @_
    );

    # get mainpage
    my $login_status = $self->login();
    return undef unless $login_status;

    my $agent = $self->AGENT();

#   If you've problems with your environmet settings activate this and "use encodings"
#   binmode(STDOUT, ":encoding(iso-8859-15)");

    $agent->field( "kontonummer", $values{'ACCOUNT'} );
    $agent->field( "zeitraum",    $values{'TIMEFRAME'} );

    if (   $values{'TIMEFRAME'} eq "variabel"
        && $values{'START_DATE'}
        && $values{'END_DATE'} )
    {
        $agent->field( "startdatum", $values{'START_DATE'} );
        $agent->field( "enddatum",   $values{'END_DATE'} );
    }

    $agent->click();
    $agent->get( $self->BASE_URL() . "/umsatzdownload.do" );

    my $content = $agent->content();
    print STDERR Dumper($content) if $self->Debug();

    my $csv_content = $self->_parse_csv($content);
    return $csv_content;
}

sub transfer {
    my $self   = shift;
    my %values = (
        SENDER_ACCOUNT   => $self->ACCOUNT(),
        RECEIVER_NAME    => "",
        RECEIVER_ACCOUNT => "",
        RECEIVER_BLZ     => "",
        RECEIVER_SAVE    => "false",
        COMMENT_1        => "",
        COMMENT_2        => "",
        AMOUNT           => "0.00",
        TAN              => "",
        @_
    );

    # get mainpage
    my $login_status = $self->login();
    return undef unless $login_status;

    my $agent = $self->AGENT();
    my $url   = $self->BASE_URL();

    $agent->get($url . "ueberweisung_per_heute_neu.do");

    ( $values{'AMOUNT_EURO'}, $values{'AMOUNT_CENT'} ) =
      split( /\.|,/, $values{'AMOUNT'} );

    $values{'AMOUNT_CENT'} = sprintf("%02d", $values{'AMOUNT_CENT'});

    $agent->field("auftraggeberKontonummer", $values{'SENDER_ACCOUNT'});
    $agent->field("empfaengerName",          $values{'RECEIVER_NAME'});
    $agent->field("empfaengerBankleitzahl",  $values{'RECEIVER_BLZ'});
    $agent->field("empfaengerKontonummer",   $values{'RECEIVER_ACCOUNT'});
    $agent->field("betragEuro",              $values{'AMOUNT_EURO'});
    $agent->field("betragCent",              $values{'AMOUNT_CENT'});
    $agent->field("verwendungszweck1",       $values{'COMMENT_1'});
    $agent->field("verwendungszweck2",       $values{'COMMENT_2'});
    $agent->click("btnNeuSpeichern");

    # get TAN fieldname, index
    my $tan_field;
    my $tan_index;
    my $tan;

    $agent->content =~ /(?:Tr|TAN)(?:[a-z].*?)\s?(\d+)/gmix;

    $tan_field = $1;
    $tan_index = $2;

    print STDERR "tan_field: $tan_field, tan_index: $tan_index\n" if $self->Debug();

    if ($tan_field && $tan_index && ref($values{'TAN'}) eq "HASH" && $values{'TAN'}->{$tan_index}) {
        print STDERR "METHOD: TAN HASH" if $self->Debug();
        $tan = $values{'TAN'}->{$tan_index};
    } elsif ($tan_field && $tan_index && ref($values{'TAN'}) eq "ARRAY") {
        print STDERR "METHOD: Object/Method" if $self->Debug();
        my $obj    = $values{'TAN'}[0];
        my $method = $values{'TAN'}[1];
        eval ( $tan = $obj->$method() );
        if ($@) {
            print "ERROR: Could not execute TAN method: $method";
            return undef;
        }
    } elsif ($tan_field && $tan_index && ref($values{'TAN'}) eq "CODE") {
        print STDERR "METHOD: CALLBACK" if $self->Debug();
        $tan = &{$values{'TAN'}}($tan_index);
    }

    print STDERR " TAN: [$tan]\n" if $self->Debug();

    if ($tan) {
	    $agent->field($tan_field, $tan_index);
	    $agent->click("btnBestaetigen");

        # lazy error checking
        if ( $agent->content() =~ m|(.*)30017(.*)| ) {
            $agent->content() =~ m|(.*?)|;
            my $error = $1;
            print "ERROR: $error";
            return;
        } else {
            my $content = $agent->content();
            return $agent->content();
        }
    } else {
        print "ERROR: Could not identify requested TAN Index #";
        return;
    }
}

sub logout {
    my $self  = shift;
    my $agent = $self->AGENT();
    my $url   = $self->BASE_URL();
    $agent->get( $url . "logout.do" );
}

sub _parse_csv {
    my $self        = shift;
    my $csv_content = shift;
    $csv_content =~ s/\r//gmi;
    $csv_content =~ s/\f//gmi;
    my @lines = split( "\n", $csv_content );
    my %data;

    my $csv = Text::CSV_XS->new(
        {
            sep_char => "\t",
            binary   => 1,      ### german umlauts...
        }
    );

    my $line_count = 0;

    foreach my $line (@lines) {
        my $status  = $csv->parse($line);
        my @columns = $csv->fields();
        $line_count++;

        ### Account Details ########################
        if ( $line_count > 3 && $line_count < 6 ) {
            $columns[0] =~ s/://;
            $data{"ACCOUNT"}{ uc( $columns[0] ) } = $columns[1];
        }

        ### Statement Details ######################
        if ( $line_count == 9 ) {
            $data{"STATEMENT"}{"START_DATE"} = $columns[0];
            $data{"STATEMENT"}{"END_DATE"}   = $columns[1];
            $data{"STATEMENT"}{"ACCOUNT_ID"} = $columns[2];
            $data{"STATEMENT"}{"SALDO"}      = $columns[3];
            $data{"STATEMENT"}{"WAEHRUNG"}   = $columns[4];
        }

        ### Transactions ###########################
        if ( $line_count > 12 && $line_count <= $#lines ) {
            my $row = $line_count - 13;
            $data{"TRANSACTION"}[$row]{"BUCHUNGSTAG"}      = $columns[0];
            $data{"TRANSACTION"}[$row]{"WERTSTELLUNGSTAG"} = $columns[1];
            $data{"TRANSACTION"}[$row]{"VERWENDUNGSZWECK"} = $columns[2];

            $columns[3] =~ s/\.//;
            $columns[3] =~ s/,/\./;

            $data{"TRANSACTION"}[$row]{"UMSATZ"}           = $columns[3];
            $data{"TRANSACTION"}[$row]{"WAEHRUNG"}         = $columns[4];
            $data{"TRANSACTION"}[$row]{"NOT_YET_FINISHED"} = $columns[5]
              if ( defined( $columns[5] ) && $columns[5] =~ m/^[^\s]$/ig );
        }
    }

    return \%data;
}

1;
__END__