File Coverage

blib/lib/Finance/AMEX/Transaction/GRRCN.pm

Criterion	Covered	Total	%
statement	78	84	92.8
branch	13	24	54.1
condition	2	4	50.0
subroutine	21	21	100.0
pod	6	6	100.0
total	120	139	86.3

package Finance::AMEX::Transaction::GRRCN 0.005;

use strict;
use warnings;

use Text::CSV;
use Carp 'croak';

use Finance::AMEX::Transaction::GRRCN::Header;
use Finance::AMEX::Transaction::GRRCN::Summary;
use Finance::AMEX::Transaction::GRRCN::TaxRecord;
use Finance::AMEX::Transaction::GRRCN::Submission;
use Finance::AMEX::Transaction::GRRCN::Transaction;
use Finance::AMEX::Transaction::GRRCN::TxnPricing;
use Finance::AMEX::Transaction::GRRCN::Chargeback;
use Finance::AMEX::Transaction::GRRCN::Adjustment;
use Finance::AMEX::Transaction::GRRCN::FeeRevenue;
use Finance::AMEX::Transaction::GRRCN::Trailer;
use Finance::AMEX::Transaction::GRRCN::Unknown;

# ABSTRACT: Parse AMEX Global Reconciliation (GRRCN)

sub new {
  my ($class, %props) = @_;

  my $type_map = {
    HEADER     => 'Finance::AMEX::Transaction::GRRCN::Header',
    SUMMARY    => 'Finance::AMEX::Transaction::GRRCN::Summary',
    TAXRECORD  => 'Finance::AMEX::Transaction::GRRCN::TaxRecord',
    SUBMISSION => 'Finance::AMEX::Transaction::GRRCN::Submission',
    TRANSACTN  => 'Finance::AMEX::Transaction::GRRCN::Transaction',
    TXNPRICING => 'Finance::AMEX::Transaction::GRRCN::TxnPricing',
    CHARGEBACK => 'Finance::AMEX::Transaction::GRRCN::Chargeback',
    ADJUSTMENT => 'Finance::AMEX::Transaction::GRRCN::Adjustment',
    FEEREVENUE => 'Finance::AMEX::Transaction::GRRCN::FeeRevenue',
    TRAILER    => 'Finance::AMEX::Transaction::GRRCN::Trailer',
  };

  my $file_format  = $props{file_format}  || 'UNKNOWN';
  my $file_version = $props{file_version} || 'UNKNOWN';

  my $self = bless {
    _type_map     => $type_map,
    _file_format  => $file_format,
    _file_version => $file_version,
  }, $class;

  return $self;
}

sub file_format {
  my ($self) = @_;
  return $self->{_file_format};
}

sub file_version {
  my ($self) = @_;
  return $self->{_file_version};
}

sub detect_file_format {
  my ($self, $line) = @_;

  if (substr($line, 0, 1) eq '"') {
    if ($line =~ m{","}xsm) {
      $self->{_file_format} = 'CSV';
    } elsif ($line =~ m{\"\t\"}xsm) {
      $self->{_file_format} = 'TSV';
    }

    return $self->{_file_format};
  }
  $self->{_file_format} = 'FIXED';
  return $self->{_file_format};
}

sub parse_line {
  my ($self, $line) = @_;

  return if not defined $line;

  if ($self->file_format eq 'UNKNOWN') {
    $self->detect_file_format($line);
  }

  my $type = $self->detect_line_type($line);

  if (exists $self->{_type_map}->{$type}) {

    my $parsed = $self->{_type_map}->{$type}->new(
      line         => $line,
      file_format  => $self->file_format,
      file_version => $self->{_file_version},
    );

    # We want to set the version when we see the header,
    # it can change how we parse some of the line types
    if ($type eq 'HEADER') {
      $self->{_file_version} = $parsed->FILE_VERSION_NUMBER;
    }

    return $parsed;
  }

  return Finance::AMEX::Transaction::GRRCN::Unknown->new(line => $line);
}

sub detect_line_type {
  my ($self, $line) = @_;

  if ($self->file_format eq 'FIXED') {
    return substr($line, 0, 10);
  }

  my $csv = Text::CSV->new({
    binary      => 1,
    quote_char  => '"',
    escape_char => "\\",
  })
    or croak 'Cannot use CSV: ' . Text::CSV->error_diag();

  $line =~ s{\s+\z}{}xsm;    # csv parser does not like trailing whitespace

  if ($self->file_format eq 'CSV') {
    $csv->sep_char(',');
  } elsif ($self->file_format eq 'TSV') {
    $csv->sep_char("\t");
  }

  if (my $status = $csv->parse($line)) {
    return ($csv->fields)[0];
  }
}

1;

__END__