File Coverage

blib/lib/File/Blarf.pm

Criterion	Covered	Total	%
statement	39	67	58.2
branch	17	48	35.4
condition	5	9	55.5
subroutine	6	7	85.7
pod	3	3	100.0
total	70	134	52.2

package File::Blarf;
{
  $File::Blarf::VERSION = '0.12';
}
# ABSTRACT: Simple reading and writing of files

use warnings;
use strict;
use 5.008;

use Fcntl qw( :flock );


sub slurp {
    my $file = shift;
    my $opts = shift || {};

    if ( -e $file && open( my $FH, '<', $file ) ) {
        flock( $FH, LOCK_SH ) if $opts->{Flock};
        my @lines = <$FH>;
        flock( $FH, LOCK_UN ) if $opts->{Flock};
        # DGR: we just read it, what could possibly go wrong?
        ## no critic (RequireCheckedClose)
        close($FH);
        ## use critic
        if (wantarray) {
            if ( $opts->{Chomp} ) {
                chomp(@lines);
            }
            return @lines;
        }
        else {
            my $out = join q{}, @lines;
            if ( $opts->{Chomp} ) {
                chomp($out);
            }
            return $out;
        }
    }
    else {
        return;
    }
}


sub blarf {
    my $file = shift;
    my $str  = shift;
    my $opts = shift || {};

    my $mode = '>';
    if ( $opts->{Append} ) {
        $mode = '>>';
    }
    # DGR: due to flock and newlines we can't be anymore brief
    ## no critic (RequireBriefOpen)
    if ( open( my $FH, $mode, $file ) ) {
        flock( $FH, LOCK_EX ) if $opts->{Flock};
        if(!print $FH $str) {
            return;
        }
        if ( $opts->{'Newline'} ) {
            if(!print $FH "\n") {
                return;
            }
        }
        flock( $FH, LOCK_UN ) if $opts->{Flock};
        if(close($FH)) {
            return 1;
        }
    }
    ## use critic

    return;
}

sub cat {
    my $source_file = shift;
    my $dest_file   = shift;
    my $opts        = shift || {};

    my $mode = '>';
    if ( $opts->{Append} ) {
        $mode = '>>';
    }
    # DGR: the files could be huge, so we MUST no read them into main memory
    ## no critic (RequireBriefOpen)
    if ( open( my $IN, '<', $source_file ) ) {
        flock( $IN, LOCK_SH ) if $opts->{Flock};
        my $status = 0;
        if ( open( my $OUT, $mode, $dest_file ) ) {
            flock( $OUT, LOCK_EX ) if $opts->{Flock};
            while ( my $line = <$IN> ) {
                if(!print $OUT $line) {
                    return;
                }
            }
            flock( $OUT, LOCK_UN ) if $opts->{Flock};
            if(close($OUT)) {
                $status = 1;
            }
        }
        flock( $IN, LOCK_UN ) if $opts->{Flock};
        # DGR: we were just reading ...
        ## no critic (RequireCheckedClose)
        close($IN);
        ## use critic
        if ($status) {
            return $status;
        }
    }
    ## use critic
    # something went wrong ...
    return;
}


1; # End of File::Blarf

__END__