File Coverage

blib/lib/Duadua/Parser.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	18	20	90.0
condition	12	12	100.0
subroutine	6	6	100.0
pod	1	1	100.0
total	79	81	97.5

package Duadua::Parser;
use strict;
use warnings;
use Duadua::Util;

my $BLANK_UA = {
    name => 'UNKNOWN',
};

sub parse {
    my ($class, $d) = @_;

    for my $m (@{$d->parsers}) {
        if ( my $res = $m->try($d) ) {
            return $res;
        }
    }

    # Blank or '-'
    if ($d->ua eq '' || $d->ua eq '-') {
        return $BLANK_UA;
    }

    if ( my $browser = $class->_detect_general_browser($d) ) {
        return $browser;
    }

    if ( my $bot = $class->_detect_general_bot($d) ) {
        return $bot;
    }

    return $BLANK_UA;
}

sub _detect_general_browser {
    my ($class, $d) = @_;

    my %h = %{$BLANK_UA};

    if ( index($d->ua, 'Mozilla/') == 0 && index($d->ua, 'rowser') > 0 ) {
        if ( $d->ua =~ m![^a-zA-Z]([a-zA-Z]+[bB]rowser)/([\d.]+)! ) {
            ($h{name}, $h{version}) = ($1, $2);
            return Duadua::Util->set_os($d, \%h);
        }
    }
}

sub _detect_general_bot {
    my ($class, $d) = @_;

    my %h = %{$BLANK_UA};

    if ( index($d->ua, 'http://') > -1 || index($d->ua, 'https://') > -1 ) {
        $h{is_bot} = 1;
        if ( index($d->ua, 'Mozilla/') != 0 && $d->ua =~ m!^([^/;]+)/(v?[\d.]+)! ) {
            my ($name, $version) = ($1, $2);
            $h{name}    = $name;
            $h{version} = $version;
        }
        elsif ( $d->ua =~ m![\s\(]([^/\s:;]+(?:bot|crawl|crawler|spider|fetcher))/(v?[\d.]+)!i ) {
            my ($name, $version) = ($1, $2);
            $h{name}    = $1;
            $h{version} = $version;
        }
        elsif ( $d->ua =~ m!([a-zA-Z0-9\-\_\.\!]+(?:bot|crawler))!i ) {
            $h{name} = $1;
        }

        return \%h;
    }
}

1;

__END__