File Coverage

blib/lib/DateTime/Format/XMLTV.pm

Criterion	Covered	Total	%
statement	23	23	100.0
branch	2	2	100.0
condition			n/a
subroutine	7	7	100.0
pod	2	2	100.0
total	34	34	100.0

#---------------------------------------------------------------------
package DateTime::Format::XMLTV;
#
# Copyright 2011 Christopher J. Madsen
#
# Author: Christopher J. Madsen
# Created: 28 Dec 2010
#
# This program is free software; you can redistribute it and/or modify
# it under the same terms as Perl itself.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See either the
# GNU General Public License or the Artistic License for more details.
#
# ABSTRACT: Parse and format XMLTV dates and times
#---------------------------------------------------------------------

use 5.008;
use strict;
use warnings;

our $VERSION = '1.001';
# This file is part of DateTime-Format-XMLTV 1.001 (March 8, 2014)

#=====================================================================
use DateTime::Format::Builder 0.80 (
  parsers => {
    parse_datetime => [
      [ preprocess => \&_parse_tz ],
      {
        length => 14,
        params => [ qw( year month day hour minute second ) ],
        regex  => qr/^(\d\d\d\d)(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)$/,
      },
      {
        length => 12,
        params => [ qw( year month day hour minute ) ],
        regex  => qr/^(\d\d\d\d)(\d\d)(\d\d)(\d\d)(\d\d)$/,
      },
      {
        length => 10,
        params => [ qw( year month day hour ) ],
        regex  => qr/^(\d\d\d\d)(\d\d)(\d\d)(\d\d)$/,
      },
      {
        length => 8,
        params => [ qw( year month day ) ],
        regex  => qr/^(\d\d\d\d)(\d\d)(\d\d)$/,
      },
      {
        length => 6,
        params => [ qw( year month ) ],
        regex  => qr/^(\d\d\d\d)(\d\d)$/,
      },
      {
        length => 4,
        params => [ qw( year ) ],
        regex  => qr/^(\d\d\d\d)$/,
      },
    ],
  },
);

*parse_date = \&parse_datetime;
*parse_time = \&parse_datetime; # XMLTV has no time-only format

#---------------------------------------------------------------------
sub _parse_tz
{
  my %args = @_;
  my ($date, $p) = @args{qw( input parsed )};

  $date =~ s/\s+\z//;           # Strip any trailing whitespace

  if ($date =~ s/\s+(\S+)\z//) {
    $p->{time_zone} = $1;
  } else {
    $p->{time_zone} = 'UTC';
  }

  return $date;
} # end _parse_tz

#---------------------------------------------------------------------
sub format_date
{
  my ($self, $dt) = @_;

  return $dt->ymd('');
}

sub format_datetime
{
  my ($self, $dt) = @_;

  return($dt->ymd('') . $dt->hms('') . ' ' .
         DateTime::TimeZone->offset_as_string($dt->offset));
}

*format_time = \&format_datetime; # XMLTV has no time-only format

#=====================================================================
# Package Return Value:

1;

__END__