File Coverage

blib/lib/Date/Calc/Iterator.pm

Criterion	Covered	Total	%
statement	66	70	94.2
branch	18	26	69.2
condition	2	6	33.3
subroutine	13	13	100.0
pod	2	2	100.0
total	101	117	86.3

package Date::Calc::Iterator;

use 5.006;
use strict;
use warnings;

our $VERSION = '1.02';

use Date::Calc qw( Delta_Days Add_Delta_Days check_date ) ;
use Ref::Util  qw( is_arrayref is_ref );
use Carp       qw( croak );

use constant FORMAT_ARRAYREF    => 1;
use constant FORMAT_ISO_DASHED  => 2;
use constant FORMAT_ISO_NO_DASH => 3;

use constant DEFAULT_STEP_SIZE  => 1;

sub new {
  my $self  = shift ;
  my %parms = @_ ;

  my $class = ref $self || $self ;

  my ($from, $from_format) = _validate_date_param(\%parms, 'from');
  my ($to,   $to_format)   = _validate_date_param(\%parms, 'to');

  # TODO: should we require that the from format matches the to format?

  if (exists($parms{step}) && $parms{step} !~ /^\d+$/) {
      croak "the 'step' parameter must be an integer";
  }

  my $object          = {
                          from   => $from,
                          to     => $to,
                          format => $from_format,
                          delta  => 0,
                        };

  $object->{step}     = exists($parms{step}) ? $parms{step} : DEFAULT_STEP_SIZE;
  $object->{maxdelta} = Delta_Days(@{$from}, @{$to}) ;

  return bless($object, $class);
}

sub _validate_date_param
{
    my ($params, $key) = @_;
    my $date           = $params->{$key};
    my $ymdref;
    my $format;

    croak "you must provide a '$key' date" unless defined($date);

    if (is_arrayref($date)) {
        $ymdref = $date;
        $format = FORMAT_ARRAYREF;
    }
    elsif (is_ref($date)) {
        croak "unexpected reference type for '$key' parameter";
    }
    # TODO: should probably make these [0-9] instead of \d
    elsif ($date =~ /^(\d\d\d\d)-(\d\d)-(\d\d)$/) {
        $ymdref = [$1, $2, $3];
        $format = FORMAT_ISO_DASHED;
    }
    elsif ($date =~ /^(\d\d\d\d)(\d\d)(\d\d)$/) {
        $ymdref = [$1, $2, $3];
        $format = FORMAT_ISO_NO_DASH;
    }
    else {
        croak "unexpected '$key' date '$date'";
    }

    if (check_date(@$ymdref)) {
        return ($ymdref, $format);
    }
    else {
        croak "invalid date for '$key' parameter";
    }

}

sub next {
  my $self = shift ;

  eval { $self->isa('Date::Calc::Iterator') } ;
  die "next() is an object method" if $@ ;

  return undef if $self->{delta} > $self->{maxdelta} ;

  my @next_date = Add_Delta_Days(@{$self->{from}},$self->{delta}) ;
  $self->{delta} += $self->{step} ;
  if ($self->{format} == FORMAT_ARRAYREF) {
      return wantarray ? @next_date : \@next_date ;
  }
  elsif ($self->{format} == FORMAT_ISO_DASHED) {
    return sprintf('%d-%.2d-%.2d', @next_date);
  }
  else {
    return sprintf('%d%.2d%.2d', @next_date);
  }
}

1;

__END__