File Coverage

blib/lib/Data/Remember/Memory.pm

Criterion	Covered	Total	%
statement	40	43	93.0
branch	8	10	80.0
condition	5	9	55.5
subroutine	7	7	100.0
pod	4	4	100.0
total	64	73	87.6

use strict;
use warnings;

package Data::Remember::Memory;
{
  $Data::Remember::Memory::VERSION = '0.140490';
}
# ABSTRACT: a short-term memory brain plugin for Data::Remember

use Scalar::Util qw/ reftype /;


sub new {
    my $class = shift;
    bless { brain => {} }, $class;
}


sub remember {
    my $self = shift;
    my $que  = shift;
    my $fact = shift;

    my $last_que = pop @$que;
    my $que_remaining = scalar @$que;

    my $object = $self->{brain};
    for my $que_entry (@$que) {
        if (defined $object->{$que_entry}) {

            if ($que_remaining == 0
                    or (ref $object->{$que_entry}
                        and reftype $object->{$que_entry} eq 'HASH')) {
                $object = $object->{$que_entry};
            }

            # overwrite previous non-hash fact with something more agreeable
            else {
                $object = $object->{$que_entry} = {}
            }
        }

        else {
            $object = $object->{$que_entry} = {};
        }

        $que_remaining--;
    }

    $object->{$last_que} = $fact;
}


sub recall {
    my $self = shift;
    my $que  = shift;

    my $object = $self->{brain};
    for my $que_entry (@$que) {
        return unless ref $object and reftype $object eq 'HASH';

        if (defined $object->{$que_entry}) {
            $object = $object->{$que_entry};
        }

        else {
            return;
        }
    }

    return scalar $object;
}


sub forget {
    my $self = shift;
    my $que  = shift;

    my $last_que = pop @$que;

    my $object = $self->{brain};
    for my $que_entry (@$que) {
        if (defined $object->{$que_entry}) {
            $object = $object->{$que_entry};
        }
        else {
            return;
        }
    }

    delete $object->{$last_que};
}


1;

__END__