File Coverage

blib/lib/Data/Page/Nav.pm

Criterion	Covered	Total	%
statement	49	51	96.0
branch	20	24	83.3
condition	10	17	58.8
subroutine	9	9	100.0
pod	4	4	100.0
total	92	105	87.6

package Data::Page::Nav;

use strict;
use warnings;
use base 'Data::Page';

our $VERSION = '0.01';

__PACKAGE__->mk_accessors(qw/number_of_pages/);

sub new {
    my $class = shift;
    my $self  = {
        _first_nav_page => undef,
        _last_nav_page  => undef,
    };
    bless( $self, $class );

    my ( $total_entries, $entries_per_page, $current_page, $number_of_pages ) = @_;
    $self->total_entries( $total_entries       || 0 );
    $self->entries_per_page( $entries_per_page || 10 );
    $self->current_page( $current_page         || 1 );
    $self->number_of_pages( $number_of_pages   || 10 );

    return $self;
}

sub pages_nav {
    my $self = shift;

    my $total = int(shift || $self->number_of_pages);
    my $rest  = $total % 2;
    my $half  = ($total - $rest) / 2;

    $self->{_first_nav_page} = $self->_start_nav($total, $half, $rest);
    $self->{_last_nav_page}  = $self->_end_nav($total, $half);

    return wantarray
         ? ($self->first_nav_page .. $self->last_nav_page)
         : [$self->first_nav_page .. $self->last_nav_page];
}

sub first_nav_page {
    my $self = shift;
    my $number_of_pages = shift;

    return shift @{$self->pages_nav($number_of_pages)}
        if $number_of_pages || !$self->{_first_nav_page};

    return $self->{_first_nav_page} if $self->{_first_nav_page};

    return;
}

sub last_nav_page {
    my $self = shift;
    my $number_of_pages = shift;

    return pop @{$self->pages_nav($number_of_pages)}
        if $number_of_pages || !$self->{_last_nav_page};

    return $self->{_last_nav_page} if $self->{_last_nav_page};

    return;
}

sub _start_nav {
    my ($self, $total, $half, $rest) = @_;

    if ($self->current_page > $half) {
        if (($self->current_page + $half) > $self->last_page) {
            if ($self->last_page > $total) {
                return ($self->last_page - $total) + 1;
            }
        } else {
            return ($self->current_page - $half) + ($rest ? 0 : 1);
        }
    }

    return 1;
}

sub _end_nav {
    my ($self, $total, $half) = @_;

    if ($self->last_page > ($self->current_page + $half)) {
        if ($self->current_page <= $half) {
            if ($self->last_page > $total) {
                return $total;
            }
        } else {
            return $self->current_page + $half;
        }
    }

    return $self->last_page;
}

1;

__END__