File Coverage

blib/lib/Data/Iterator/SlidingWindow.pm

Criterion	Covered	Total	%
statement	53	53	100.0
branch	11	12	91.6
condition	11	11	100.0
subroutine	11	11	100.0
pod	2	2	100.0
total	88	89	98.8

package Data::Iterator::SlidingWindow;
use strict;
use warnings;
use 5.008001;
use parent 'Exporter';
use Carp qw(croak);
use overload
    '<>'     => sub { shift->next() },
    fallback => 1;

our $VERSION = '0.05';

our @EXPORT = qw(iterator);

sub _new {
    my $class = shift;
    my %args  = @_;

    my $window_size = $args{window_size};
    my $src_stuff   = $args{data_source};

    if ( !defined $window_size || $window_size !~ /^[0-9]+$/ || $window_size == 0 ) {
        croak "window size must be positive integer.";
    }

    my $src_type = ref( $src_stuff || q{} ) || q{};
    if ( !( $src_type eq 'CODE' || $src_type eq 'ARRAY' ) ) {
        croak "data_source must be CODE reference or ARRAY refernce.";
    }

    my $source;
    if ( $src_type eq 'ARRAY' ) {
        $source = sub {
            shift @$src_stuff;
        };
    }
    else {
        $source = $src_stuff;
    }

    # Initialize current window
    my @current_window;
    while ( @current_window < $window_size ) {
        my $next = $source->();
        last if !defined $next;
        push @current_window, $next;
    }

    my $self = {
        _window_size    => $window_size,
        _source         => $source,
        _current_window => \@current_window,
    };

    return bless $self, $class;
}

sub next {
    my $self = shift;
    my $ret  = [ @{ $self->{_current_window} } ];
    return if @$ret != $self->{_window_size};
    shift @{ $self->{_current_window} };
    my $next = $self->{_source}->();
    if ( defined $next ) {
        push @{ $self->{_current_window} }, $next;
    }
    return $ret;
}

sub iterator {
    my ( $window_size, $data_source ) = @_;
    return __PACKAGE__->_new(
        window_size => $window_size,
        data_source => $data_source,
    );
}

1;
__END__