File Coverage

lib/Dancer/Plugin/TimeoutManager.pm

Criterion	Covered	Total	%
statement	65	67	97.0
branch	18	22	81.8
condition	18	21	85.7
subroutine	12	12	100.0
pod	0	1	0.0
total	113	123	91.8

package Dancer::Plugin::TimeoutManager;

use strict;
use warnings;
our $VERSION = '0.10'; # VERSION

use Try::Tiny;
use Dancer ':syntax';
use Dancer::Exception ':all';
use Dancer::Plugin;
use Carp 'croak';
use List::MoreUtils qw( none);


if (  exists $ENV{DISABLE_DANCER_TIMEOUT} && $ENV{DISABLE_DANCER_TIMEOUT} ) {
    set disable_timeout => 1;
}

#get the timeout from headers
hook(before => sub {
    var header_timeout => request->header('X-Dancer-Timeout');
});

register 'timeout' => \&timeout;

register_exception ('InvalidArgumentNumber',
    message_pattern => "the number of arguments must 3 or 4, you've got %s",
);

register_exception ('InvalidMethod',
    message_pattern => "method must be one in get, put, post, delete and %s is used as a method",
);


my @authorized_methods = ('get', 'post', 'put', 'delete');

=method exception_message

return the exception message
This method can be used to catch the exception if the code used already contained a try catch

=cut

sub exception_message {

    return 'Route Timeout Detected';
}

=method timeout

Method that manage the timeout on a dancer request

=cut

sub timeout {
    my ($timeout,$method, $pattern, @rest);

    if (scalar(@_) == 4) {
        ($timeout,$method, $pattern, @rest) = @_;
    }
    elsif(scalar(@_) == 3) {
        ($method, $pattern, @rest) = @_;
    }
    else {
         raise InvalidMethod => scalar(@_);
    }

    my $code;
    for my $e (@rest) { $code = $e if (ref($e) eq 'CODE') }
    my $request;

    #if method is not valid an exception is done
    if ( none { $_ eq lc($method) } @authorized_methods ) {
        raise InvalidMethod => $method;
    }

    my $exception_message = exception_message();
    my $timeout_route = sub {
        my $response;

        # maximum possible timeout, set in the plugin config
        my $conf = plugin_setting();

        #if timeout is not defined but a value is set in the headers for timeout
        my $request_timeout = 0;
        $request_timeout = $timeout if (defined $timeout);
        $request_timeout = vars->{header_timeout} if (!defined $timeout && defined vars->{header_timeout});
        $request_timeout = $conf->{max_timeout}
          if (defined $conf->{max_timeout} && defined $request_timeout && $request_timeout && $conf->{max_timeout} < $request_timeout);

        # if timeout is not defined or equal 0 the timeout manager is not used
        my $timeout_exception;

        if (!$request_timeout || (defined setting('disable_timeout') && setting('disable_timeout'))) {
            $response = $code->();
        }
        else {
           try {
                local $SIG{ALRM} = sub { croak ($exception_message); };
                alarm($request_timeout);

                $response = $code->();
                alarm(0);
            }
            catch {
                $timeout_exception = $_;
            };

            alarm(0);
        }

        # Timeout detected
        if ($timeout_exception && $timeout_exception =~ /$exception_message/) {
            my $response_with_timeout = Dancer::Response->new(
                status  => 408,
                content => "Request Timeout : more than $request_timeout seconds elapsed."
            );
            return $response_with_timeout;
        }

        # Preserve exceptions caught during route call
        croak $@ if $@;

        # else everything is allright
        return $response;
    };

    my @compiled_rest;

    for my $e (@rest) {
        if (ref($e) eq 'CODE') {
            push @compiled_rest, $timeout_route;
        }
        else {
            push @compiled_rest, $e;
        }
    }

    # declare the route in Dancer's registry
    any [$method] => $pattern, @compiled_rest;
}

register_plugin;

1;
__END__