File Coverage

blib/lib/DBIx/Skinny/ProxyTable/Rule.pm

Criterion	Covered	Total	%
statement	9	44	20.4
branch	0	8	0.0
condition	0	3	0.0
subroutine	3	11	27.2
pod	1	7	14.2
total	13	73	17.8

package DBIx::Skinny::ProxyTable::Rule;
use strict;
use warnings;
use Carp qw();

sub new {
    my ($class, $proxy_table, $base, @args) = @_;
    my $self = {
        proxy_table => $proxy_table,
        base_table  => $base,
    };
    bless $self, $class;
    $self->{table_name} = $self->_table_name(@args);
    $self->{proxy_table}->set($self->{base_table}, $self->table_name);
    return $self;
}

sub table_name {
    my $self = $_[0];
    $self->{table_name};
}

sub _table_name {
    my ($self, @args) = @_;

    my $rule = $self->{proxy_table}->{skinny}->schema->proxy_table_rules->{$self->{base_table}};
    unless ( $rule ) {
        Carp::croak("Cant' find proxy_table_rules for @{[ $self->{base_table} ]}");
    }
    my ($func, @default_args) = @{$rule};
    if ( ref $func && ref $func eq "CODE" ) {
        return $func->(@default_args, @args);
    } else {
        return $self->$func(@default_args, @args);
    }
}

sub copy_table {
    my $self = $_[0];
    $self->{proxy_table}->copy_table($self->{base_table}, $self->table_name);
}

sub strftime {
    my ($self, $tmpl, $dt) = @_;
    $dt->strftime($tmpl);
}

sub named_strftime {
    my ($self, $tmpl, $key, %args) = @_;
    if ( $args{$key} ) {
        return $args{$key}->strftime($tmpl);
    } else {
        Carp::croak("can't find key $key for argument");
    }
}

sub sprintf {
    my ($self, $tmpl, @args) = @_;
    CORE::sprintf($tmpl, @args);
}

sub keyword {
    my ($self, $tmpl, %args) = @_;
    my @binds;
    $tmpl =~ s{<(%[^:]+):([A-Za-z_][A-Za-z0-9_]*)>}{
        Carp::croak("$2 is not exists in hash") if !exists $args{$2};
        push @binds, $args{$2};
        $1
    }ge;
    return CORE::sprintf($tmpl, @binds);
}

1;
__END__