File Coverage

blib/lib/Brickyard/Accessor.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	6	8	75.0
condition			n/a
subroutine	12	12	100.0
pod			n/a
total	58	60	96.6

use 5.010;
use warnings;
use strict;

package Brickyard::Accessor;
BEGIN {
  $Brickyard::Accessor::VERSION = '1.111750';
}

# ABSTRACT: Accessor generator for Brickyard classes

sub import {
    shift;
    my %args     = @_;
    my $pkg      = caller(0);
    my %key_ctor = (rw => \&_mk_accessors);
    for my $key (sort keys %key_ctor) {
        next unless $args{$key};
        die "value of the '$key' parameter should be an arrayref"
          unless ref $args{$key} eq 'ARRAY';
        $key_ctor{$key}->($pkg, @{ $args{$key} });
    }
    _mk_new($pkg) if $args{new};
    1;
}

sub _mk_new {
    my $pkg = shift;
    no strict 'refs';
    *{"${pkg}::new"} = sub {
        my $class = shift;
        bless {@_}, $class;
    };
}

sub _mk_accessors {
    my $pkg = shift;
    for my $n (@_) {
        no strict 'refs';
        *{"${pkg}::${n}"} = __make_rw($n);
    }
}

sub __make_rw {
    my $n = shift;
    sub {
        $_[0]->{$n} = $_[1] if @_ == 2;
        $_[0]->{$n};
    };
}
1;


__END__