File Coverage

blib/lib/Bot/Cobalt/Plugin/RandomQuote.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package Bot::Cobalt::Plugin::RandomQuote;
# ABSTRACT: Bot::Cobalt plugin for retrieving random quotes from files
$Bot::Cobalt::Plugin::RandomQuote::VERSION = '0.001';
use strict;
use warnings;

use Bot::Cobalt;
use Bot::Cobalt::Common;

use Path::Tiny;

sub new { bless {}, shift }

sub quotesdir { shift->{quotesdir} }
sub commands  { shift->{commands}  }

sub Cobalt_register {
   my $self = shift;
   my $core = shift;
   my $conf = $core->get_plugin_cfg($self);

   my $quotesdir = $conf->{quotedir} // path( $core->var, 'quotes' );
   $self->{quotesdir} = path($quotesdir)->absolute;
   $self->{commands}  = [];

   my @files = $self->quotesdir->children;

   foreach my $file (@files) {
      next if not $file->is_file;

      my $cmd = lc( $file->basename(qr/\..+$/) );
      my $handler = sub {
         my $self = shift;
         my $core = shift;
         my $msg  = ${ shift() };

         my $channel = $msg->channel;
         my $context = $msg->context;
         my $nick    = $msg->src_nick;

         my @lines = grep { /\W/ } ( $file->lines );
         my $num   = int(rand(@lines));
         my $quote = $lines[$num];

         $quote =~ s/\$\{nick\}/$nick/g;
         $quote =~ s/\$\{channel\}/$channel/g;

         broadcast( 'message', $context, $channel, $quote );

         return PLUGIN_EAT_ALL;
      };

      {
         no strict 'refs';
         *{__PACKAGE__ . '::Bot_public_cmd_' . $cmd } = $handler;
      }

      logger->info('Registered, command: !' . $cmd);

      push @{ $self->{commands} }, $cmd;

      register( $self, 'SERVER', 'public_cmd_' . $cmd );
   }

   return PLUGIN_EAT_NONE;
}

sub Cobalt_unregister {
   my $self = shift;
   my $core = shift;

   foreach my $cmd (@{ $self->commands }) {
      unregister($self, 'SERVER', 'public_cmd_' . $cmd);
   }

   logger->info("Unregistered");

   return PLUGIN_EAT_NONE;
}

1;

__END__