File Coverage

blib/lib/Beam/Event.pm

Criterion	Covered	Total	%
statement	17	17	100.0
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod	2	2	100.0
total	25	25	100.0

package Beam::Event;
our $VERSION = '1.005';
# ABSTRACT: Base Event class

use strict;
use warnings;

use Moo;
use Types::Standard qw(:all);

#pod =attr name
#pod
#pod The name of the event. This is the string that is given to L.
#pod
#pod =cut

has name => (
    is          => 'ro',
    isa         => Str,
    required    => 1,
);

#pod =attr emitter
#pod
#pod The emitter of this event. This is the object that created the event.
#pod
#pod =cut

has emitter => (
    is          => 'ro',
    isa         => ConsumerOf['Beam::Emitter'],
    required    => 1,
);

#pod =attr is_default_stopped
#pod
#pod This is true if anyone called L on this event.
#pod
#pod Your L should check this attribute before trying to do
#pod what the event was notifying about.
#pod
#pod =cut

has is_default_stopped => (
    is          => 'rw',
    isa         => Bool,
    default     => sub { 0 },
);

#pod =attr is_stopped
#pod
#pod This is true if anyone called L on this event.
#pod
#pod When using L, this is checked automatically
#pod after every callback, and event processing is stopped if this is true.
#pod
#pod =cut

has is_stopped => (
    is          => 'rw',
    isa         => Bool,
    default     => sub { 0 },
);

#pod =method stop_default ()
#pod
#pod Calling this will cause the default behavior of this event to be stopped.
#pod
#pod B Your event-emitting object must check L for this
#pod behavior to work.
#pod
#pod =cut

sub stop_default {
    my ( $self ) = @_;
    $self->is_default_stopped( 1 );
}

#pod =method stop ()
#pod
#pod Calling this will immediately stop any further processing of this event.
#pod Also calls L.
#pod
#pod =cut

sub stop {
    my ( $self ) = @_;
    $self->stop_default;
    $self->is_stopped( 1 );
}

1;

__END__