File Coverage

blib/lib/ArangoDB2/Graph/VertexCollection.pm

Criterion	Covered	Total	%
statement	22	41	53.6
branch	1	8	12.5
condition	0	5	0.0
subroutine	8	13	61.5
pod	6	6	100.0
total	37	73	50.6

package ArangoDB2::Graph::VertexCollection;

use strict;
use warnings;

use base qw(
    ArangoDB2::Base
);

use Data::Dumper;
use JSON::XS;

use ArangoDB2::Graph::Vertex;

my $JSON = JSON::XS->new->utf8;



# create
#
# POST /_api/gharial/graph-name/vertex
sub create
{
    my($self, $args) = @_;
    # process request args
    $args = $self->_build_args($args, ['name']);
    # make request
    my $res = $self->arango->http->post(
        $self->api_path('gharial', $self->graph->name, 'vertex'),
        undef,
        $JSON->encode({collection => $args->{name}}),
    ) or return;
    # set name
    $self->name($args->{name});
    # update parent graph object with response data
    $self->graph->_build_self($res, ['edgeDefinitions', 'name', 'orphanCollections']);
    # register instance
    $self->graph->vertexCollections->{$self->name} = $self;

    return $self;
}

# delete
#
# DELETE /_api/gharial/graph-name/vertex/collection-name
sub delete
{
    my($self, $args) = @_;
    # process request args
    $args = $self->_build_args($args, ['dropCollection', 'name']);
    # make request
    my $res = $self->arango->http->delete(
        $self->api_path('gharial', $self->graph->name, 'vertex', delete $args->{name}),
        $args,
    ) or return;
    # update parent graph object with response data
    $self->graph->_build_self($res, ['edgeDefinitions', 'name', 'orphanCollections']);
    # unregister instance
    delete $self->graph->vertexCollections->{$self->name};

    return $res;
}

# dropCollection
#
# get/set dropCollection
sub dropCollection { shift->_get_set_bool('dropCollection', @_) }

# list
#
# GET /_api/gharial/graph-name/vertex
sub list
{
    my($self) = @_;

    my $res = $self->arango->http->get(
        $self->api_path('gharial', $self->graph->name, 'vertex')
    ) or return;

    return $res->{collections};
}

# vertex
#
# return an ArangoDB2::Graph::Vertex object
sub vertex
{
    my($self, $name) = @_;

    if (defined $name) {
        return $self->vertices->{$name} ||= ArangoDB2::Graph::Vertex->new(
            $self->arango,
            $self->database,
            $self->graph,
            $self,
            $name,
        );
    }
    else {
        return ArangoDB2::Graph::Vertex->new(
            $self->arango,
            $self->database,
            $self->graph,
            $self,
        );
    }
}

# vertices
#
# index of ArangoDB2::Graph::Vertex objects by name
sub vertices { $_[0]->{vertices} ||= {} }

# _class
#
# internally treat this as a collection
sub _class { 'collection' }

1;

__END__