File Coverage

blib/lib/App/todoist.pm

Criterion	Covered	Total	%
statement	21	60	35.0
branch	0	20	0.0
condition	0	12	0.0
subroutine	7	12	58.3
pod	0	5	0.0
total	28	109	25.6

package App::todoist;
$App::todoist::VERSION = '0.01';
use 5.006;
use strict;
use warnings;
use Net::Todoist;
use Carp qw/ croak /;
use AppConfig::Std;
use File::Slurp qw/ read_file /;

sub new
{
    my $class = shift;
    my $obj   = bless({}, $class)
                || croak "Can't instantiate App::todoist\n";

    return $obj;
}

sub process_options
{
    my ($self, $opts) = @_;

    my $config        = AppConfig::Std->new()
                        || croak "Can't instantiate AppConfig::Std\n";

    $config->define('token',      { ARGCOUNT => 1 });
    $config->define('project',    { ARGCOUNT => 1 });
    $config->define('importfile', { ARGCOUNT => 1, ALIAS => 'i' });
    $config->define('priority',   { ARGCOUNT => 1, ALIAS => 'p', DEFAULT => 4 });

    if (defined($ENV{HOME}) && -f "$ENV{HOME}/.todoist") {
        my $filename = "$ENV{HOME}/.todoist";
        if (((stat($filename))[2] & 36) != 0) {
            croak "your config file ($filename) is readable by others!\n";
        }
        $config->file($filename) || exit 1;
    }

    if ($opts->{argv}) {
        $config->args($opts->{argv})
        || die "run \"$0 -help\" to see valid options\n";
    }

    croak "you must provide a token\n"   unless $config->token;
    croak "you must provide a project\n" unless $config->project;

    $self->{config} = $config;

    my $todoist = Net::Todoist->new(token => $config->token)
                  || croak "failed to connect to todoist\n";

    $self->{todoist} = $todoist;

    if ($config->project) {
        my @projects = $todoist->getProjects;
        my ($project) = grep { $_->{name} eq $config->project } @projects;
        if (not defined $project) {
            croak "couldn't find project '", $config->project, "' in todoist\n"
        }
        $self->{project_id} = $project->{id};
    }
}

sub config
{
    my $self = shift;
    return $self->{config};
}

sub todoist
{
    my $self = shift;
    return $self->{todoist};
}

sub run
{
    my ($self, $opts) = @_;

    $self->process_options($opts);

    if ($self->config->importfile) {
        my @tasks = read_file($self->config->importfile, chomp => 1);
        foreach my $task (@tasks) {
            $self->todoist->addItem(
                project_id => $self->{project_id},
                content    => $task,
                priority   => $self->config->priority,
            );
        }
        printf STDERR "%d tasks added from %s\n", int(@tasks),
                      $self->config->importfile;
    }
}

1;

=head1 NAME

App::todoist - implements the meat of a command-line interface to todoist.com

=head1 SYNOPSIS

 Add something here

=head1 DESCRIPTION

This module implements the functionality behind the C script.
You should look at the documentation for that.

=head1 REPOSITORY

L

=head1 AUTHOR

Neil Bowers [e-mail]

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2013 by Neil Bowers .

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut