File Coverage

blib/lib/App/envfile.pm

Criterion	Covered	Total	%
statement	48	56	85.7
branch	15	20	75.0
condition	2	2	100.0
subroutine	9	10	90.0
pod	3	3	100.0
total	77	91	84.6

package App::envfile;

use strict;
use warnings;
use 5.008_001;
use Carp ();

our $VERSION = '0.07';

our $EXTENTIONS_MAP = {
    pl   => 'Perl',
    perl => 'Perl',
    js   => 'JSON',
    json => 'JSON',
    yml  => 'YAML',
    yaml => 'YAML',
};

sub new {
    my $class = shift;
    bless {}, $class;
}

sub run_with_env {
    my ($self, $env, $commands) = @_;
    local %ENV = %ENV;
    for my $key (keys %$env) {
        $ENV{$key} = $env->{$key};
    }
    exec(@$commands);
}

sub parse_envfile {
    my ($self, $file) = @_;
    Carp::croak "Usage: $self->parse_envfile(\$file)" unless defined $file;

    my $env = {};
    return $env if $env = $self->_try_any_config_file($file);

    open my $fh, '<', $file or Carp::croak "$file: $!";
    while (defined (my $line = readline $fh)) {
        chomp $line;
        next if index($line, '#') == 0;
        next if $line =~ /^\s*$/;
        my ($key, $value) = $self->_parse_line($line);
        $env->{$key} = $value;
    }
    close $fh;

    return $env;
}

sub _try_any_config_file {
    my ($self, $file) = @_;

    my ($ext) = $file =~ /\.(\w+)$/;
    if (my $type = $EXTENTIONS_MAP->{lc($ext || '')}) {
        my $env;
        if ($type eq 'Perl') {
            $env = do "$file";
            die $@ if $@;
        }
        else {
            require Data::Encoder;
            $env = Data::Encoder->load($type)->decode($self->_slurp($file));
        }
        die "$file: Should be return HASHREF\n" unless ref $env eq 'HASH';
        return $env;
    }

    return;
}

sub _slurp {
    my ($self, $file) = @_;
    my $data = do {
        local $\;
        open my $fh, '<', $file or die "$file: $!\n";
        <$fh>;
    };
    return $data;
}

sub _parse_line {
    my ($self, $line) = @_;
    my ($key, $value) = map { my $str = $_; $str =~ s/^\s+|\s+$//g; $str } split '=', $line, 2;
    return $key, $value;
}

1;
__END__