File Coverage

blib/lib/App/Sysadmin/Log/Simple/Twitter.pm

Criterion	Covered	Total	%
statement	23	40	57.5
branch	1	10	10.0
condition	1	3	33.3
subroutine	6	7	85.7
pod	2	2	100.0
total	33	62	53.2

package App::Sysadmin::Log::Simple::Twitter;
use strict;
use warnings;
use autodie qw(:file :filesys);
use Config::General qw(ParseConfig);
use Path::Tiny;

# ABSTRACT: a Twitter-logger for App::Sysadmin::Log::Simple
our $VERSION = '0.009'; # VERSION


sub new {
    my $class = shift;
    my %opts  = @_;
    my $app   = $opts{app};

    my $oauth_file;
    if ($app->{oauth_file}) {
        $oauth_file = $app->{oauth_file};
    }
    else {
        require File::HomeDir;

        my $HOME = File::HomeDir->users_home(
            $app->{user} || $ENV{SUDO_USER} || $ENV{USER}
        );
        $oauth_file = path($HOME, '.sysadmin-log-twitter-oauth');
    }

    return bless {
        oauth_file  => $oauth_file,
        do_twitter  => $app->{do_twitter},
    }, $class;
}


sub log {
    my $self     = shift;
    my $logentry = shift;

    return unless $self->{do_twitter};

    require Net::Twitter::Lite::WithAPIv1_1;

    warn "You should do: chmod 600 $self->{oauth_file}\n"
        if ($self->{oauth_file}->stat->mode & 07777) != 0600; ## no critic (ValuesAndExpressions::ProhibitLeadingZeros)
    my $conf = Config::General->new($self->{oauth_file});
    my %oauth = $conf->getall();

    my $ua = __PACKAGE__
        . '/' . (defined __PACKAGE__->VERSION ? __PACKAGE__->VERSION : 'dev');
    my $t = Net::Twitter::Lite::WithAPIv1_1->new(
        consumer_key        => $oauth{consumer_key},
        consumer_secret     => $oauth{consumer_secret},
        access_token        => $oauth{oauth_token},
        access_token_secret => $oauth{oauth_token_secret},
        ssl                 => 1,
        useragent           => $ua,
    );
    $t->access_token($oauth{oauth_token});
    $t->access_token_secret($oauth{oauth_token_secret});

    my $result = $t->update($logentry);
    die 'Something went wrong' unless $result->{text} eq $logentry;

    my $url = 'https://twitter.com/'
        . $result->{user}->{screen_name}
        . '/status/' . $result->{id_str};
    return "Posted to Twitter: $url";
}

1;

__END__