File Coverage

blib/lib/App/Raps2/UI.pm

Criterion	Covered	Total	%
statement	18	69	26.0
branch	0	10	0.0
condition	0	9	0.0
subroutine	6	13	46.1
pod	7	7	100.0
total	31	108	28.7

package App::Raps2::UI;

use strict;
use warnings;
use 5.010;

use Carp qw(cluck confess);
use POSIX;
use Term::ReadLine;

our $VERSION = '0.53';

sub new {
	my ($obj) = @_;

	my $ref = {};

	$ref->{term_readline} = Term::ReadLine->new('App::Raps2');

	return bless( $ref, $obj );
}

sub list {
	my ( $self, @list ) = @_;

	my $format = "%-20s %-20s %s\n";

	if ( not $self->{list}->{header} ) {
		printf( $format, map { $_->[0] } @list );
		$self->{list}->{header} = 1;
	}
	printf( $format, map { $_->[1] // q{} } @list );

	return 1;
}

sub read_line {
	my ( $self, $str, $pre ) = @_;

	my $input = $self->{term_readline}->readline( "${str}: ", $pre );

	return $input;
}

sub read_multiline {
	my ( $self, $str ) = @_;

	my $in;

	say "${str} (^D or empty line to quit)";

	while ( my $line = $self->read_line('multiline') ) {
		$in .= "${line}\n";
	}

	return $in;
}

sub read_pw {
	my ( $self, $str, $verify ) = @_;

	my ( $in1, $in2 );
	my $term = POSIX::Termios->new();

	$term->getattr(0);
	$term->setlflag( $term->getlflag() & ~POSIX::ECHO );
	$term->setattr( 0, POSIX::TCSANOW );

	print "${str}: ";
	$in1 = readline(STDIN);
	print "\n";

	if ($verify) {
		print 'Verify: ';
		$in2 = readline(STDIN);
		print "\n";
	}

	$term->setlflag( $term->getlflag() | POSIX::ECHO );
	$term->setattr( 0, POSIX::TCSANOW );

	if ( $verify and $in1 ne $in2 ) {
		confess('Input lines did not match');
	}

	chomp $in1;

	return $in1;
}

sub to_clipboard {
	my ( $self, $str, $cmd ) = @_;

	$cmd //= 'xclip -l 1';

	open( my $clipboard, q{|-}, $cmd )
	  or return;

	print $clipboard $str;

	close($clipboard)
	  or cluck("Failed to close pipe to ${cmd}: ${!}");

	return 1;
}

sub output {
	my ( $self, @out ) = @_;

	for my $pair (@out) {
		printf( "%-8s : %s\n", $pair->[0], $pair->[1] // q{}, );
	}

	return 1;
}

1;

__END__