File Coverage

blib/lib/App/Prove/Elasticsearch/Harness.pm

Criterion	Covered	Total	%
statement	43	47	91.4
branch	4	6	66.6
condition			n/a
subroutine	8	8	100.0
pod	3	3	100.0
total	58	64	90.6

# PODNAME:  App::Prove::Elasticsearch::Harness
# ABSTRACT: Harness for uploading test results to elasticsearch

package App::Prove::Elasticsearch::Harness;
$App::Prove::Elasticsearch::Harness::VERSION = '0.001';
use strict;
use warnings;

use parent qw/TAP::Harness/;

# inject parser_class as Test::Rail::Parser.
sub new {
    my $class   = shift;
    my $arg_for = shift;
    $arg_for->{parser_class} = 'App::Prove::Elasticsearch::Parser';
    my $self = $class->SUPER::new($arg_for);
    return $self;
}

sub make_parser {
    my ($self, $job) = @_;

    my $args = $self->SUPER::_get_parser_args($job);

    my @relevant_keys =
      qw{SERVER_HOST SERVER_PORT CLIENT_INDEXER CLIENT_BLAMER CLIENT_VERSIONER CLIENT_PLATFORMER CLIENT_AUTODISCOVER};
    my @keys_filtered = grep {
        my $subj = $_;
        grep { $_ eq $subj } @relevant_keys
    } keys(%ENV);
    foreach my $key (@keys_filtered) {
        my $km = lc($key);
        $km =~ s/_/./g;
        $args->{$km} = $ENV{$key};
        $self->{$km} = $ENV{$key};
    }

    $self->SUPER::_make_callback('parser_args', $args, $job->as_array_ref);
    my $parser = $self->SUPER::_construct($self->SUPER::parser_class, $args);

    $self->SUPER::_make_callback('made_parser', $parser, $job->as_array_ref);
    my $session =
      $self->SUPER::formatter->open_test($job->description, $parser);

    return ($parser, $session);
}

sub runtests {
    my ($self, @tests) = @_;

    if ($ENV{CLIENT_AUTODISCOVER}) {
        my $searcher = $self->_require_deps();
        @tests = $self->_filter_tests_with_results($searcher, @tests);
    }

    return $self->SUPER::runtests(@tests);
}

sub _filter_tests_with_results {
    my ($self, $searcher, @tests) = @_;
    my $indexer = $ENV{CLIENT_INDEXER};
    my $conf    = {
        'server.host'       => $ENV{SERVER_HOST},
        'server.port'       => $ENV{SERVER_PORT},
        'client.versioner'  => $ENV{CLIENT_VERSIONER},
        'client.platformer' => $ENV{CLIENT_PLATFORMER},
    };
    my $s = $searcher->new($conf, $indexer);
    return $s->filter(@tests);
}

sub _require_deps {

    eval "require $ENV{CLIENT_INDEXER}";
    die $@ if $@;

    my $runner =
      "App::Prove::Elasticsearch::Searcher::$ENV{CLIENT_AUTODISCOVER}";

    eval "require $runner";
    die $@ if $@;

    return $runner;
}

1;

__END__