File Coverage

blib/lib/App/OATH/Crypt/CBC.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	3	4	75.0
condition			n/a
subroutine	10	10	100.0
pod	3	3	100.0
total	57	58	98.2

package App::OATH::Crypt::CBC;
our $VERSION = '1.20150914'; # VERSION

use strict;
use warnings;
use Convert::Base32;
use Crypt::CBC;
use Digest::MD5;
use String::Random qw{ random_string };

sub new {
    my ( $class, $args ) = @_;
    my $self = {
        'password' => $args->{'password'},
        'type'     => $args->{'type'},
        'check'    => 'oath',
    };
    bless $self, $class;
    return $self;
}

sub _get_crypt_object {
    my ( $self ) = @_;
    my $password = $self->{'password'};

    my $crypt = Crypt::CBC->new({
        'key'    => $password,
        'cipher' => $self->{'type'},
        'salt'   => 1,
    });
    return $crypt;
}

sub encrypt {
    my ( $self, $data ) = @_;
    my $worker = $self->_get_crypt_object();
    my $u = random_string( '..........' ) . ' ' . $self->{'check'} . ' ' . $data;

    my $e = $worker->encrypt( $u );
    $e = encode_base32( $e );
    return $e;
}

sub decrypt {
    my ( $self, $data ) = @_;
    my $worker = $self->_get_crypt_object();
    my $e = decode_base32( $data );
    my $u = $worker->decrypt($e);
    my ( $salt, $check, $payload ) = split( ' ', $u );
    $check = q{} if ! $check;
    if ( $check ne $self->{'check'} ) {
        return;
    }
    return $payload;
}

1;

__END__

=head1 NAME

App::OATH::Crypt::CBC - Crypto modules for Simple OATH authenticator

=head1 DESCRIPTION

Crypto modules for CBC methods, this includes Rijndael and Blowfish

=head1 SYNOPSIS

Handles encryption and decryption for CBC Rijndael and Blowfish ciphers

=head1 METHODS

=over

=item I<new()>

Instantiate a new object

=item I<encrypt($data)>

Encrypt the given data

=item I<decrypt($data)>

Decrypt the given data

=back

=head1 DEPENDENCIES

  Convert::Base32
  Crypt::Blowfish
  Crypt::CBC
  Crypt::Rijndael
  Digest::MD5
  String::Random

=head1 AUTHORS

Marc Bradshaw E<lt>[e-mail]<gt>

=head1 COPYRIGHT

Copyright 2015

This library is free software; you may redistribute it and/or
modify it under the same terms as Perl itself.