File Coverage

blib/lib/AnyEvent/WebService/Tracks/Todo.pm

Criterion	Covered	Total	%
statement	18	66	27.2
branch	0	20	0.0
condition			n/a
subroutine	6	17	35.2
pod	11	11	100.0
total	35	114	30.7

package AnyEvent::WebService::Tracks::Todo;

use strict;
use warnings;
use parent 'AnyEvent::WebService::Tracks::Resource';

use Carp qw(croak);
use Scalar::Util qw(looks_like_number);

use namespace::clean;

our $VERSION = '0.02';

__PACKAGE__->readonly(qw/completed_at created_at id recurring_todo_id updated_at/);
__PACKAGE__->accessor(qw/description due notes show_from/);

# here, but not actually accessible: context_id project_id state

sub resource_path {
    return 'todos';
}

sub xml_root {
    return 'todo';
}

sub is_complete {
    my ( $self ) = @_;

    return $self->{'state'} eq 'completed';
}

sub is_active {
    my ( $self ) = @_;

    return $self->{'state'} eq 'active';
}

sub is_project_hidden {
    my ( $self ) = @_;

    return $self->{'state'} eq 'project_hidden';
}

sub is_deferred {
    my ( $self ) = @_;

    return $self->{'state'} eq 'deferred';
}

sub complete {
    my ( $self ) = @_;

    $self->{'state'}           = 'completed';
    $self->{'_dirty'}{'state'} = 1;

    if(defined $self->{'show_from'}) {
        undef $self->{'show_from'};
        $self->{'_dirty'}{'show_from'} = 1;
    }
}

sub activate {
    my ( $self ) = @_;

    $self->{'state'}           = 'active';
    $self->{'_dirty'}{'state'} = 1;

    if(defined $self->{'show_from'}) {
        undef $self->{'show_from'};
        $self->{'_dirty'}{'show_from'} = 1;
    }
}

sub defer {
    my ( $self, $amount ) = @_;

    my $show_from;

    if(! ref($amount)) {
        $show_from = DateTime->now->add(days => $amount);
    } elsif(ref($amount) eq 'DateTime') {
        $show_from = $amount;
    } elsif(ref($amount) eq 'DateTime::Duration') {
        $show_from = DateTime->now->add_duration($amount);
    }

    $self->{'show_from'}           = $show_from;
    $self->{'_dirty'}{'show_from'} = 1;
}

sub context {
    my ( $self, $cb_or_ctx ) = @_;

    if(ref($cb_or_ctx) eq 'CODE') {
        my $id = $self->{'context_id'};
        if(defined $id) {
            $self->{'parent'}->fetch_single('contexts', $id,
                'AnyEvent::WebService::Tracks::Context', $cb_or_ctx);
        } else {
            $cb_or_ctx->(undef);
        }
    } else {
        $self->{'context_id'} = $cb_or_ctx->id;
        $self->{'_dirty'}{'context_id'} = 1;
    }
}

sub project {
    my ( $self, $cb_or_proj ) = @_;

    if(ref($cb_or_proj) eq 'CODE') {
        my $id = $self->{'project_id'};
        if(defined $id) {
            $self->{'parent'}->fetch_single('projects', $id,
                'AnyEvent::WebService::Tracks::Project', $cb_or_proj);
        } else {
            $cb_or_proj->(undef);
        }
    } else {
        if(defined $cb_or_proj) {
            $self->{'project_id'} = $cb_or_proj->id;
        } else {
            $self->{'project_id'} = undef;
        }
        $self->{'_dirty'}{'project_id'} = 1;
    }
}

1;

__END__