File Coverage

blib/lib/AnyEvent/Pcap.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package AnyEvent::Pcap;
use strict;
use warnings;
use Carp;
use AnyEvent;
use AnyEvent::Pcap::Utils;
use Net::Pcap;
use base qw(Class::Accessor::Fast);

our $VERSION = '0.00002';

__PACKAGE__->mk_accessors($_) for qw(utils device filter packet_handler fd);

sub new {
    my $class = shift;
    my $self = bless {@_}, $class;
    $self->utils( AnyEvent::Pcap::Utils->new );
    return $self;
}

sub _setup_pcap {
    my $self = shift;

    my $err;
    my $device = $self->device || sub {
        $self->device( Net::Pcap::pcap_lookupdev( \$err ) );
      }
      ->();
    croak $err if $err;

    my $pcap = Net::Pcap::pcap_open_live( $device, 1024, 1, 0, \$err );
    croak $err if $err;

    my ( $address, $netmask );
    Net::Pcap::lookupnet( $device, \$address, \$netmask, \$err );
    croak $err if $err;

    my $filter;
    my $filter_string = $self->filter || sub {
        $self->filter("");
      }
      ->();

    Net::Pcap::compile( $pcap, \$filter, $filter_string, 0, $netmask );
    Net::Pcap::setfilter( $pcap, $filter );

    my $fd = Net::Pcap::fileno($pcap);
    $self->fd($fd);
    return $pcap;
}

sub run {
    my $self = shift;

    my $pcap = $self->_setup_pcap();

    my $packet_handler = $self->packet_handler || sub {
        $self->packet_handler( sub { } );
      }
      ->();

    my $io;
    $io = AnyEvent->io(
        fh   => $self->fd,
        poll => 'r',
        cb   => sub {
            my @pending;
            Net::Pcap::dispatch(
                $pcap, -1,
                sub {
                    my $header = $_[1];
                    my $packet = $_[2];
                    push @{ $_[0] }, ( $header, $packet );
                },
                \@pending
            );
            $packet_handler->( @pending, $io );
        }
    );
}

1;
__END__