File Coverage

blib/lib/Math/Business/ConnorRSI.pm

Criterion	Covered	Total	%
statement	80	82	97.5
branch	22	30	73.3
condition	11	14	78.5
subroutine	11	13	84.6
pod	0	9	0.0
total	124	148	83.7

package Math::Business::ConnorRSI;

use strict;
use warnings;
use Carp;

use Math::Business::RSI;

1;

sub tag { (shift)->{tag} }

sub recommended { (shift)->new() }

sub new {
    my $class = shift;
    my $this = bless {}, $class;

    $this->set_cdays(shift ||   3);
    $this->set_sdays(shift ||   2);
    $this->set_pdays(shift || 100);

    $this->{cRSI} = Math::Business::RSI->new($this->{cdays});
    $this->{sRSI} = Math::Business::RSI->new($this->{sdays});

    return $this;
}

sub reset {
    my $this = shift;

    delete $this->{cy};
    delete $this->{st};

    $this->{cRSI} = Math::Business::RSI->new($this->{cdays}) if exists $this->{cRSI};
    $this->{sRSI} = Math::Business::RSI->new($this->{sdays}) if exists $this->{sRSI};
    $this->{prar} = [];
}

sub set_cdays {
    my $this = shift;
    my $arg  = int(shift);

    croak "days must be a positive non-zero integer" if $arg <= 0;

    $this->{cdays} = $arg;
    $this->{tag} = "CRSI($this->{cdays},$this->{sdays},$this->{pdays})"
       unless grep {not defined} @$this{qw(cdays sdays pdays)};

    $this->reset;
}

sub set_sdays {
    my $this = shift;
    my $arg  = int(shift);

    croak "days must be a positive non-zero integer" if $arg <= 0;

    $this->{sdays} = $arg;
    $this->{tag} = "CRSI($this->{cdays},$this->{sdays},$this->{pdays})"
       unless grep {not defined} @$this{qw(cdays sdays pdays)};

    $this->reset;
}

sub set_pdays {
    my $this = shift;
    my $arg  = int(shift);

    croak "days must be a positive non-zero integer" if $arg <= 0;

    $this->{pdays} = $arg;
    $this->{tag} = "CRSI($this->{cdays},$this->{sdays},$this->{pdays})"
       unless grep {not defined} @$this{qw(cdays sdays pdays)};

    $this->reset;
}

sub insert {
    my $this = shift;
    my $close_yesterday = $this->{cy};
    my $streak          = $this->{st} || 0;

    my $sRSI  = $this->{sRSI};
    my $cRSI  = $this->{cRSI};
    my $prar  = $this->{prar};
    my $pdays = $this->{pdays};

    # we store 1 extra so we can compare $pdays values
    my $pdaysp1 = $pdays + 1;

    while( defined( my $close_today = shift ) ) {
        if( defined $close_yesterday ) {
            if( $close_yesterday > $close_today ) {
                $streak = $streak >= 0 ? -1 : $streak-1;

            } elsif( $close_yesterday < $close_today ) {
                $streak = $streak <= 0 ? 1 : $streak+1;

            } else {
                $streak = 0;
            }

            $sRSI->insert($streak);

            push @$prar, ($close_today - $close_yesterday)/$close_yesterday;
            shift @$prar while @$prar > $pdaysp1;
        }

        $cRSI->insert($close_today);

        $close_yesterday = $close_today;
    }

    $this->{srsi} = my $srsi = $sRSI->query;
    $this->{crsi} = my $crsi = $cRSI->query;

    if( defined $srsi and defined $crsi and @$prar==$pdaysp1 ) {
        my $v = $prar->[-1];
        my $p = 0;
        my $i = $#$prar;

        # we skip the first one, cuz that's $v
        while( (--$i) >= 0 ) {
            $p ++ if $prar->[$i] < $v;
        }

        $this->{prank} = my $PR = 100 * ($p/$pdays);
        $this->{connor} = ( $srsi + $crsi + $PR ) / 3;
    }

    $this->{cy} = $close_yesterday;
    $this->{st} = $streak;
}

sub query {
    my $this = shift;

    return $this->{connor};
}

__END__