File Coverage

blib/lib/Math/Business/EMA.pm

Criterion	Covered	Total	%
statement	37	39	94.8
branch	8	10	80.0
condition	3	3	100.0
subroutine	7	9	77.7
pod	0	6	0.0
total	55	67	82.0

package Math::Business::EMA;

use strict;
use warnings;
use Carp;

1;

sub tag { (shift)->{tag} }

sub recommended { croak "no recommendation" }

sub new {
    my $class = shift;
    my $this = bless {
        EMA => undef,
        R   => 0,
        R1  => 0,
    }, $class;

    my $days = shift;
    if( defined $days ) {
        $this->set_days( $days );
    }

    return $this;
}

sub set_days {
    my $this = shift;
    my $arg  = int(shift);

    croak "days must be a positive non-zero integer" if $arg <= 0;

    $this->{R}    = 2.0 / (1.0 + $arg);
    $this->{R1}   = (1 - $this->{R});
    $this->{days} = $arg;

    $this->{tag} = "EMA($this->{days})";
}

sub insert {
    my $this = shift;

    croak "You must set the number of days before you try to insert" if not $this->{R};

    while( defined(my $Yt  = shift) ) {
        if( defined(my $e = $this->{EMA}) ) {
            $this->{EMA} = ( $this->{R} * $Yt ) + ( $this->{R1} * $e );

        } else {
            my ($p,$N);
            if( ref($p = $this->{_p}) and (($N = @$p) >= $this->{days}-1) ) {
                my $sum = 0;
                   $sum += $_ for @$p;

                $this->{EMA} = ( $this->{R} * $Yt ) + ( $this->{R1} * ($sum/$N) );
                delete $this->{_p};

            } else {
                push @{$this->{_p}}, $Yt;
            }
        }
    }
}

sub query {
    my $this = shift;

    return $this->{EMA};
}

__END__