File Coverage

blib/lib/ore.pm

Criterion	Covered	Total	%
statement	55	83	66.2
branch	2	8	25.0
condition			n/a
subroutine	17	23	73.9
pod	0	14	0.0
total	74	128	57.8

package ore;

use 5.014;

use strict;
use warnings;
use routines;

use base 'Exporter';

use Data::Dump;
use Data::Object::Space;

no strict 'refs';

our @EXPORT=('dd');

our $VERSION = '0.02'; # VERSION

sub import {
  my $args = [map { /([^=]+)=(.*)/; $ENV{$1} = $2; $1 } @ARGV];

  new_vars([@$args ? @$args : keys %ENV]);
  use_vars([@$args ? @$args : keys %ENV]);

  ore->export_to_level(1, @_);
}

fun new_vars($args) {
  [map new_vars_pump(new_vars_form($_)), grep /^New_/, @$args]
}

fun new_vars_args($spec) {
  [map { /^\$(\w+)$/ ? ${"ore::$1"} : $_ } @$spec[2..$#$spec]]
}

fun new_vars_form($name) {
  new_vars_make(new_vars_spec($name))
}

fun new_vars_make($spec) {
  [$spec->[1], Data::Object::Space->new($spec->[0])->build(@{new_vars_args($spec)})]
}

fun new_vars_name($name) {
  $name =~ s/^New_//gr =~ s/_/\//gr
}

fun new_vars_spec($name) {
  [new_vars_name($name), split /;\s*/, $ENV{$name}]
}

fun new_vars_pump($conf) {
  ${"ore::$$conf[0]"} = $$conf[1]; push @EXPORT, '$'.$$conf[0]; $conf
}

fun use_vars($args) {
  [map use_vars_pump(use_vars_form($_)), grep /^Use_/, @$args]
}

fun use_vars_args($spec) {
  [map { /^\$(\w+)$/ ? ${"ore::$1"} : $_ } @$spec[2..$#$spec]]
}

fun use_vars_form($name) {
  use_vars_make(use_vars_spec($name))
}

fun use_vars_make($spec) {
  [$spec->[1], Data::Object::Space->new($spec->[0])]
}

fun use_vars_name($name) {
  $name =~ s/^Use_//gr =~ s/_/\//gr
}

fun use_vars_spec($name) {
  [use_vars_name($name), split /;\s*/, $ENV{$name}]
}

fun use_vars_pump($conf) {
  ${"ore::$$conf[0]"} = $$conf[1]; push @EXPORT, '$'.$$conf[0]; $conf
}

1;

=encoding utf8

=head1 NAME

ore

=cut

=head1 ABSTRACT

Sugar for Perl 5 one-liners

=cut

=head1 SYNOPSIS

  BEGIN {
    $ENV{New_File_Temp} = 'ft';
  }

  use ore;

  $ft

=cut

=head1 DESCRIPTION

This package provides automatic object instantiation based on environment
variables. This package exists because I was bored and inspired by L<new>.

=head2 examples

Simple command-line example using env vars to drive object instantiation:

  $ New_File_Temp=ft perl -More -e 'dd $ft'

  # "File::Temp"

Another simple command-line example using env vars to return a
L<Data::Object::Space> object which calls C<children> and returns an arrayref
of L<Data::Object::Space> objects:

  $ Use_DBI=dbi perl -More -e 'dd $dbi->children'

  # [
  #   ...,
  #   "DBI/DBD",
  #   "DBI/Profile",
  #   "DBI/ProfileData",
  #   "DBI/ProfileDumper",
  #   ...,
  # ]

Here's another simple command-line example using args as env vars with ordered
variable interpolation:

  $ perl -More -E 'dd $pt' New_File_Temp=ft New_Path_Tiny='pt; $ft'

  # /var/folders/pc/v4xb_.../T/JtYaKLTTSo

=cut

=head1 AUTHOR

Al Newkirk, C<[e-mail]>

=head1 LICENSE

Copyright (C) 2011-2019, Al Newkirk, et al.

This is free software; you can redistribute it and/or modify it under the terms
of the The Apache License, Version 2.0, as elucidated in the L<"license
file"|https://github.com/iamalnewkirk/ore/blob/master/LICENSE>.

=head1 PROJECT

L<Wiki|https://github.com/iamalnewkirk/ore/wiki>

L<Project|https://github.com/iamalnewkirk/ore>

L<Initiatives|https://github.com/iamalnewkirk/ore/projects>

L<Milestones|https://github.com/iamalnewkirk/ore/milestones>

L<Contributing|https://github.com/iamalnewkirk/ore/blob/master/CONTRIBUTE.md>

L<Issues|https://github.com/iamalnewkirk/ore/issues>

=cut