File Coverage

blib/lib/YA/CLI/ActionRole.pm

Criterion	Covered	Total	%
statement	47	47	100.0
branch	18	20	90.0
condition	2	2	100.0
subroutine	16	16	100.0
pod	7	8	87.5
total	90	93	96.7

package YA::CLI::ActionRole;
our $VERSION = '0.004';
use Moo::Role;
use namespace::autoclean;

# ABSTRACT: Action handler role

use YA::CLI::Usage;
use Getopt::Long;
use List::Util qw(none any);

requires qw(
    action
    run
);

has _cli_args => (
  is        => 'ro',
  predicate => '_has_cli_args',
  writer    => '_set_cli_args',
  init_args => undef,
  default   => sub { {} },
);

sub cli_options {
    return;
}

sub usage_pod {
    return;
}

sub BUILD {
    my ($self, $args) = @_;

    foreach (keys %$args) {
        delete $args->{$_} if $self->can($_);
    }
    $self->_set_cli_args($args) if %$args;
}

sub new_from_args {
    my ($class, $args) = @_;
    return $class->new($class->get_opts($args));
}

sub get_opts {
    my ($class, $args) = @_;

    my $p = Getopt::Long::Parser->new(
        config => [qw(no_auto_abbrev) ]
    );

    my %cli_args;
    $p->getoptionsfromarray($args, \%cli_args, $class->cli_options);
    return %cli_args;
}

sub has_action {
    my $self = shift;
    my $action  = shift;
    my $subaction = shift;

    return if none { $action eq $_ } $self->action;

    if ($self->can('subaction')) {
        return 0 unless defined $subaction;
        return any { $subaction eq $_ } $self->subaction;
    }
    return defined $subaction ? 0 : 1;
}

sub as_help {
    my ($self, $rc, $message) = @_;

    return YA::CLI::Usage->new(
        rc => ($rc // 0),
        $message ? (message  => $message) : (),
        $self->_get_podfile_for_usage,
    );
}

sub as_manpage {
    my ($self) = @_;

    return YA::CLI::Usage->new(
        rc      => 0,
        verbose => 2,
        $self->_get_podfile_for_usage,
    );
}


sub _get_podfile_for_usage {
    my $self = shift;
    my $podfile;
    if (my $pod = $self->usage_pod) {
        $podfile = $pod == 1? $self : $pod;
    }
    return $podfile ? ( pod_file => $podfile ) : ();
}

1;

__END__