File Coverage

blib/lib/XSLT/Dependencies.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package XSLT::Dependencies;

use vars qw ($VERSION);
$VERSION = '0.2';

use strict;
use XML::LibXML;
use File::Spec;
use Cwd qw(realpath);

sub new {
    my $class = shift;

    my $this = {
        start => undef,
        inc   => {},
    };
    bless $this, $class;

    return $this;
}

sub explore {
    my ($this, $filename) = @_;

    $this->{start} = realpath($filename);
    $this->{inc} = {};
    $this->dep_list($this->{start});

    return grep {$_ ne $this->{start}} keys %{$this->{inc}};
}

sub dep_list {
    my ($this, $filepath) = @_;

    return [] if defined $this->{inc}{$filepath};

    $this->{inc}{$filepath} = 1;

    my ($volume, $directory, $file) = File::Spec->splitpath($filepath);

    my $parser = new XML::LibXML;
    my $doc = $parser->parse_file($filepath);
    my $root = $doc->documentElement();
    my @dependencies = $root->findnodes('//xsl:include | //xsl:import');

    my @deps;
    for my $dependency (@dependencies) {
        my $relative_href = $dependency->find('string(@href)')->value();
        my $absolute_path = realpath(File::Spec->catfile($directory, $relative_href));

        push @deps, $this->dep_list($absolute_path);
    }

    return \@deps;
}

1;

__END__