File Coverage

blib/lib/XML/RSS/FromAtom.pm

Criterion	Covered	Total	%
statement	22	24	91.6
branch			n/a
condition			n/a
subroutine	8	8	100.0
pod			n/a
total	30	32	93.7

########################################################################
#
#    XML::RSS::FromAtom
#
#    Copyright 2005, Marcus Thiesen ([e-mail])  All rights reserved.
#
#    This program is free software; you can redistribute it and/or modify
#    it under the terms of either:
#
#    a) the GNU General Public License as published by the Free Software
#    Foundation; either version 1, or (at your option) any later
#       version, or
#
#    b) the "Artistic License" which comes with Perl.
#
#    On Debian GNU/Linux systems, the complete text of the GNU General
#    Public License can be found in `/usr/share/common-licenses/GPL' and
#    the Artistic Licence in `/usr/share/common-licenses/Artistic'.
#
#    This program is distributed in the hope that it will be useful,
#    but WITHOUT ANY WARRANTY; without even the implied warranty of
#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
########################################################################

package XML::RSS::FromAtom;

use common::sense;

use DateTime;
use DateTime::Format::ISO8601;
use DateTime::Format::Mail;

use Moo;

use Try::Tiny;

use XML::Atom::Syndication::Feed;
use XML::RSS;

# Version set by dist.ini; do not change here.
our $VERSION = '0.02_03'; # VERSION

has 'syndicator' => (
    is => 'ro',
    lazy => 1,
    builder => 'build_syndicator' );

sub build_syndicator {
    my $self = shift;
    return XML::Atom::Syndication::Feed->new(\$self->content);
}

has 'rss_processor' => (
    is => 'ro',
    lazy => 1,
    builder => 'build_rss_processor',
    handles => [qw(add_item channel)] );

sub build_rss_processor {
    return XML::RSS->new(version => '2.0');
}

has 'content' => (
    is => 'rw'
);

sub parse {
    my $self = shift;
    my $text = shift;

    $self->content( $text );
    return $self->atom_to_rss();
}

sub atom_to_rss {
    my $self = shift;
    my $doc = $self->syndicator();

    my $feed_title       = $doc->title->body();
    my $feed_description = $doc->subtitle->body();
    my $feed_link        = $doc->link->href();

    $self->channel(title => $feed_title) if ($feed_title);
    $self->channel(description => $feed_description) if ($feed_description);
    $self->channel(link => $feed_link) if ($feed_link);

    my @entries = $doc->entries();
    for my $e (@entries) {
        my $desc = '';
        $desc = $e->summary->body();
        my $content =
            try { $e->content->body() }
            catch { undef };
        if (defined($content)  &&
            length($content) > length($desc)) {
            $desc = $$content;
        }

        my $title = $e->title->body();

        my $mod = $e->modified();
        my $upd = $e->updated();
        my $ts = defined($mod) ? $mod : $upd;
        my $dt = DateTime::Format::ISO8601->parse_datetime( $ts );

        my $link = $e->link->href();
        my $author = $e->author->name();

        $self->add_item(
                          title => $title,
                          link  => $link,
                          description => $desc,
                          pubDate => DateTime::Format::Mail->format_datetime($dt),
                          author => $author ? $author : undef,
                          );
    }

    return $self->rss_processor;
}

# ABSTRACT: create a XML::RSS object out of an Atom feed

1;

__END__