File Coverage

blib/lib/XML/Grammar/Fortune.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package XML::Grammar::Fortune;

use warnings;
use strict;

use Fatal (qw(open));

use File::Spec;

use MooX qw/late/;

use XML::GrammarBase::Role::RelaxNG v0.2.2;
use XML::GrammarBase::Role::XSLT v0.2.2;

with ('XML::GrammarBase::Role::RelaxNG');
with XSLT(output_format => 'html');

has '+module_base' => (default => 'XML-Grammar-Fortune');
has '+rng_schema_basename' => (default => 'fortune-xml.rng');


has '+to_html_xslt_transform_basename' =>
    (default => 'fortune-xml-to-html.xslt');

has '_mode' => (is => 'rw', init_arg => 'mode');
has '_output_mode' => (is => 'rw', init_arg => 'output_mode',);

=head1 NAME

XML::Grammar::Fortune - convert the FortunesXML grammar to other formats and from plaintext.

=head1 VERSION

Version 0.0512

=cut

our $VERSION = '0.0512';


=head1 SYNOPSIS

    use XML::Grammar::Fortune;

    # Validate files.

    my $validator =
        XML::Grammar::Fortune->new(
            {
                mode => "validate"
            }
        );

    # Returns 0 upon success - dies otherwise
    exit($validator->run({input => "my-fortune-file.xml"}));

    # Convert files to XHTML.

    my $converter =
        XML::Grammar::Fortune->new(
            {
                mode => "convert_to_html",
                output_mode => "filename"
            }
        );

    $converter->run(
        {
            input => "my-fortune-file.xml",
            output => "resultant-file.xhtml",
        }
    );

=head1 FUNCTIONS

=head2 my $processor = XML::Grammar::Fortune->new({mode => $mode, input => $in, output => $out, output_mode => "string",});

Creates a new processor with mode $mode, output_mode "string", and input and output files.

=head2 $self->run({ %args})

Runs the processor. If $mode is "validate", validates the document.

%args may contain:

=over 4

=item * xslt_params

Parameters for the XSLT stylesheet.

=item * input

Input source - depends on input_mode.

=item * output

Output destination - depends on output mode.

=back

=cut

sub run
{
    my $self = shift;
    my $args = shift;

    my $xslt_params = $args->{'xslt_params'} || {};

    my $output = $args->{'output'};
    my $input = $args->{'input'};

    my $mode = $self->_mode();

    if ($mode eq "validate")
    {
        return $self->rng_validate_file($input);
    }
    elsif ($mode eq "convert_to_html")
    {
        my $translate = sub {
            my ($medium, $encoding) = @_;

            return $self->perform_xslt_translation(
                {
                    output_format => 'html',
                    source => {file => $input},
                    output => $medium,
                    encoding => $encoding,
                    xslt_params => $xslt_params,
                }
            );
        };
        if ($self->_output_mode() eq "string")
        {
            $$output .= $translate->('string', 'bytes');
        }
        else
        {
            $translate->({file => $output}, 'utf8');
        }
    }

    return;
}

1; # End of XML::Grammar::Fortune

__END__