File Coverage

blib/lib/XML/Crawler.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package XML::Crawler;

use strict;
use warnings;

use English qw( -no_match_vars $EVAL_ERROR );
use XML::LibXML;
require Exporter;

our @ISA = qw( Exporter );

our @EXPORT_OK = qw(
    xml_to_ra
);

our $VERSION = '0.01';

sub xml_to_ra {
    my ($xml) = @_;

    my $doc;

    eval {
        $doc = XML::LibXML->load_xml( string => $xml );
    };

    return
        if $EVAL_ERROR;

    return {}
        if not $doc;

    return _crawl($doc);
}

sub _crawl {
    my ( $node ) = @_;

    my $name       = $node->nodeName();
    my %attributes = map { ( $_->nodeName() => $_->getValue() ) } grep { $_ } $node->attributes();
    my $text;
    my @children;

    my @child_nodes = $node->nonBlankChildNodes();

    if (@child_nodes) {

        @children = map { _crawl( $_ ) } @child_nodes;

        if ( @children == 1 && not ref $children[0] ) {

            $text = pop @children;
        }
    }
    else {

        $text = $node->textContent();
    }

    return $text
        if $text && $name eq '#text';

    my @result = ( $name );

    push @result, \%attributes
        if keys %attributes;

    push @result, $text
        if $text;

    push @result, \@children
        if @children;

    return \@result;
}

1;

__END__