File Coverage

lib/XML/Compile/WSS/SecToken.pm

Criterion	Covered	Total	%
statement	13	15	86.6
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	18	20	90.0

# Copyrights 2012-2013 by [Mark Overmeer].
#  For other contributors see ChangeLog.
# See the manual pages for details on the licensing terms.
# Pod stripped from pm file by OODoc 2.01.
use warnings;
use strict;

package XML::Compile::WSS::SecToken;
use vars '$VERSION';
$VERSION = '2.01';


use Log::Report 'xml-compile-wss-sig';

use XML::Compile::WSS::Util   qw/XTP10_X509v3 WSU_10 :wsm10 :wsm11 XENC_NS/;
use Scalar::Util   qw/blessed/;


sub new(@)
{   my $class = shift;
    my $args  = @_==1 ? shift : {@_};
    my $type  = delete $args->{type} || XTP10_X509v3;
    if($class eq __PACKAGE__)
    {   if($type =~ /509/)
        {   $class = 'XML::Compile::WSS::SecToken::X509v3';
        }
        else
        {   error __x"security token type {type} not (yet) supported"
              , type => $type;
        }
        eval "require $class"; panic $@ if $@;
    }
    (bless {XCWS_type => $type}, $class)->init($args);
}

sub init($)
{   my ($self, $args) = @_;
    $self->{XCWS_id}   = $args->{id}       || 'my-token';
    $self->{XCWS_enc}  = $args->{encoding} || WSM10_BASE64;
    $self->{XCWS_fp}   = $args->{fingerprint};
    $self->{XCWS_uri}  = $args->{uri}      || '#TOKEN-'.($self+0);
    $self->{XCWS_name} = $args->{name};
    $self;
}


sub fromConfig($%)
{   my ($class, $config, %args) = @_;
    $args{type} ||= XTP10_X509v3;

    return $class->new(%$config, %args)
        if ref $config eq 'HASH';

    blessed $config
        or panic "token configuration requires HASH or OBJECT.";

    return $config
        if $config->isa(__PACKAGE__);

    return $class->new(%args, certificate => $config)
        if ref $config =~ m/::X509/;  # there are a few options here

    panic "token configuration `$config' not recognized";
}

#-----------------

sub id()       {shift->{XCWS_id}}
sub type()     {shift->{XCWS_type}}
sub encoding() {shift->{XCWS_enc}}

sub fingerprint{shift->{XCWS_fp}}
sub uri()      {shift->{XCWS_uri}}
sub name()     {shift->{XCWS_name}}

#-----------------

1;

__END__