File Coverage

blib/lib/Woothee/Browser.pm

Criterion	Covered	Total	%
statement	113	118	95.7
branch	44	54	81.4
condition	6	9	66.6
subroutine	13	13	100.0
pod	0	8	0.0
total	176	202	87.1

package Woothee::Browser;

use strict;
use warnings;
use Carp;

use Woothee::Util qw/update_map update_category update_version update_os/;
use Woothee::DataSet qw/dataset/;

our $VERSION = "v1.10.0";

sub challenge_msie {
    my ($ua,$result) = @_;

    return 0 if index($ua, "compatible; MSIE") < 0 and index($ua, "Trident/") < 0 and index($ua, "IEMobile");

    my $version;
    if ($ua =~ m{MSIE ([.0-9]+);}o) {
        $version = $1;
    } elsif ($ua =~ m{Trident/([.0-9]+);}o and $ua =~ m{ rv:([.0-9]+)}o) {
        $version = $1;
    } elsif ($ua =~ m{IEMobile/([.0-9]+);}o) {
        $version = $1;
    } else {
        $version = Woothee::DataSet->const('VALUE_UNKNOWN');
    }
    update_map($result, dataset('MSIE'));
    update_version($result, $version);
    return 1;
}

sub challenge_yandex_browser {
    my ($ua, $result) = @_;

    return 0 if index($ua, "YaBrowser/") < 0;

    my $version = Woothee::DataSet->const('VALUE_UNKNOWN');

    if ($ua =~ m{YaBrowser/([.0-9]+)}o) {
        $version = $1;
    }
    update_map($result, dataset('YaBrowser'));
    update_version($result, $version);
    return 1;
}

sub challenge_vivaldi {
    my ($ua, $result) = @_;

    return 0 if index($ua, "Vivaldi/") < 0;

    my $version = Woothee::DataSet->const('VALUE_UNKNOWN');

    if ($ua =~ m{Vivaldi/([.0-9]+)}o) {
        $version = $1;
    }
    update_map($result, dataset('Vivaldi'));
    update_version($result, $version);
    return 1;
}

sub challenge_safari_chrome { # and Opera(blink)
    my ($ua,$result) = @_;

    return 0 if index($ua, "Safari/") < 0;

    my $version = Woothee::DataSet->const('VALUE_UNKNOWN');

    if ($ua =~ m{(?:Edge|Edg|EdgiOS|EdgA)/([.0-9]+)}o) {
        # MS Edge
        $version = $1;
        update_map($result, dataset("Edge"));
        update_version($result, $version);
        return 1;
    }

    if ($ua =~ m{FxiOS/([.0-9]+)}o) {
        # Firefox for iOS
        $version = $1;
        update_map($result, dataset("Firefox"));
        update_version($result, $version);
        return 1;
    }

    if ($ua =~ m{(?:Chrome|CrMo|CriOS)/([.0-9]+)}o) {
        # Opera (blink)
        if ($ua =~ m{OPR/([.0-9]+)}o) {
            $version = $1;
            update_map($result, dataset("Opera"));
            update_version($result, $version);
            return 1;
        }

        #WebView
        if (index($ua, "wv") > -1) {
            return 0;
        }

        # Chrome
        $version = $1;
        update_map($result, dataset("Chrome"));
        update_version($result, $version);
        return 1;
    }

    # Safari
    if ($ua =~ m{Version/([.0-9]+)}o) {
        $version = $1;
    }
    update_map($result, dataset("Safari"));
    update_version($result, $version);
    return 1;
}

sub challenge_firefox {
    my ($ua,$result) = @_;

    return 0 if index($ua, "Firefox/") < 0;

    my $version;
    if ($ua =~ m{Firefox/([.0-9]+)}o) {
        $version = $1;
    }
    else {
        $version = Woothee::DataSet->const('VALUE_UNKNOWN');
    }
    update_map($result, dataset("Firefox"));
    update_version($result, $version);
    return 1;
}

sub challenge_opera {
    my ($ua,$result) = @_;

    return 0 if index($ua, "Opera") < 0;

    my $version;
    if ($ua =~ m{Version/([.0-9]+)}o) {
	$version = $1;
    }
    elsif ($ua =~ m{Opera[/ ]([.0-9]+)}o) {
        $version = $1;
    }
    else {
        $version = Woothee::DataSet->const('VALUE_UNKNOWN');
    }
    update_map($result, dataset("Opera"));
    update_version($result, $version);
    return 1;
}

sub challenge_webview {
    my ($ua,$result) = @_;


    my $version = Woothee::DataSet->const('VALUE_UNKNOWN');

    # iOS
    if ($ua =~ m{iP(hone;|ad;|od) .*like Mac OS X}o) {
        return 0 if index($ua, "Safari/") > -1;

        if ($ua =~ m{Version/([.0-9]+)}o) {
            $version = $1;
        }

        update_version($result, $version);
        update_map($result, dataset("Webview"));
        return 1;
    }
    elsif (index($ua, "wv") > -1) { #WebView
        if ($ua =~ m{Version/([.0-9]+)}o) {
            $version = $1;
        }

        update_version($result, $version);
        update_map($result, dataset("Webview"));
        return 1;
    }

    return 0;
}


sub challenge_sleipnir {
    my ($ua,$result) = @_;

    return 0 if index($ua, "Sleipnir/") < 0;

    my $version;
    if ($ua =~ m{Sleipnir/([.0-9]+)}o) {
        $version = $1;
    }
    else {
        $version = Woothee::DataSet->const('VALUE_UNKNOWN');
    }
    update_map($result, dataset("Sleipnir"));
    update_version($result, $version);

    # Sleipnir's user-agent doesn't contain Windows version, so put 'Windows UNKNOWN Ver'.
    # Sleipnir is IE component browser, so for Windows only.
    my $win = dataset("Win");
    update_category($result, $win->{Woothee::DataSet->const('KEY_CATEGORY')});
    update_os($result, $win->{Woothee::DataSet->const('KEY_NAME')});

    return 1;
}

1;

__END__