File Coverage

blib/lib/Win32/Vcpkg/Package.pm

Criterion	Covered	Total	%
statement	39	42	92.8
branch	10	14	71.4
condition	2	3	66.6
subroutine	12	12	100.0
pod	7	7	100.0
total	70	78	89.7

package Win32::Vcpkg::Package;

use strict;
use warnings;
use 5.008001;
use Win32::Vcpkg;
use Path::Tiny ();

# ABSTRACT: Interface to Microsoft Vcpkg Packages
our $VERSION = '0.04'; # VERSION


sub new
{
  my($class, %args) = @_;

  my $root    = defined $args{root} ? Path::Tiny->new($args{root}) : Win32::Vcpkg->root;
  my $triplet = $args{triplet} || Win32::Vcpkg->perl_triplet;
  my @lib     = @{ $args{lib} || [] };
  my $debug   = defined $args{debug} ? $args{debug} : $ENV{PERL_WIN32_VCPKG_DEBUG};

  my $libdir = $root->child('installed', $triplet, 'lib');
  $libdir    = $libdir->parent->child('debug','lib') if $debug;
  my $libs   = "-LIBPATH:$libdir";

  my $cflags = "-I@{[ $root->child('installed', $triplet, 'include') ]}";

  my @include =
    defined $args{include}
    ? (ref $args{include} eq 'ARRAY' ? @{$args{include}} : ($args{include}))
    : ();

  foreach my $include (@include)
  {
    $cflags .= " -I@{[ $root->child('installed', $triplet, 'include', $include) ]}";
  }

  foreach my $lib (@lib)
  {
    if(-f $libdir->child("$lib.lib"))
    {
      $libs .= " $lib.lib";  # Question: should this be an absolute path?
    }
    else
    {
      require Carp;
      Carp::croak("unable to find $lib");
    }
  }

  bless {
    name    => $args{_name},
    version => $args{_version},
    root    => $root,
    triplet => $triplet,
    cflags  => $cflags,
    libs    => $libs,
  }, $class;
}


sub name { shift->{name} }


sub version { shift->{version} }


sub root { shift->{root} }


sub triplet { shift->{triplet} }


sub cflags { shift->{cflags} }


sub libs { shift->{libs} }

1;

__END__