File Coverage

blib/lib/Win32/FileTime.pm

Criterion	Covered	Total	%
statement	4	6	66.6
branch			n/a
condition			n/a
subroutine	2	2	100.0
pod			n/a
total	6	8	75.0

package Win32::FileTime;

use Carp;
use Win32::API;
use Win32API::File qw/ :ALL /;

use strict;
use vars qw/ $VERSION /;

$VERSION = '0.04';


sub Access {
    my ( $self, @args ) = @_;
    return $self->getTime( $self->{'ACCESS'}, @args );
}


sub Create {
    my ( $self, @args ) = @_;
    return $self->getTime( $self->{'CREATE'}, @args );
}


sub Modify {
    my ( $self, @args ) = @_;
    return $self->getTime( $self->{'MODIFY'}, @args );
}


sub getTime {
    my ( $self, $FileTimePointer, @args ) = @_;

    my $LocalTime = pack( 'LL', 0, 0 );
    my $FileTimeToLocalFileTime = Win32::API->new(
        'kernel32',
        'FileTimeToLocalFileTime',
        [ 'P', 'P' ],
        'I'
    );
    $FileTimeToLocalFileTime->Call( $FileTimePointer, $LocalTime );

    my $SystemTime = pack( 'SSSSSSSS', 0, 0, 0, 0, 0, 0, 0, 0 );

    my $FileTimeToSystemTime = Win32::API->new(
        'kernel32',
        'FileTimeToSystemTime',
        [ 'P', 'P' ],
        'I'
    );
    $FileTimeToSystemTime->Call( $LocalTime, $SystemTime );

    my @time = unpack( 'SSSSSSSS', $SystemTime );

    my %filetime = (
        'year'      =>  $time[0],
        'month'     =>  $time[1],
        'wday'      =>  $time[2],
        'day'       =>  $time[3],
        'hour'      =>  $time[4],
        'minute'    =>  $time[5],
        'second'    =>  $time[6],
        'msecond'   =>  $time[7]
    );

    return @time unless scalar @args;

    my @return;
    foreach (@args) {
        defined $filetime{$_} or croak( __PACKAGE__, '->getTime : Unknown time field argument passed to object method' );
        push @return, $filetime{$_};
    }
    return @return;
}


sub new {
    my ( $class, $filename ) = @_;

    my $self = {};
    $self->{'FILENAME'} = $filename;
    $self->{'HFILE'} = CreateFile(
        $self->{'FILENAME'},
        GENERIC_READ(),
        FILE_SHARE_READ(),
        [],
        OPEN_EXISTING(),
        0,
        []
    ) or croak( __PACKAGE__, '->new : Cannot read file - ', $self->{'FILENAME'} );

    my %filetime = (
        'create'    =>  undef,
        'access'    =>  undef,
        'modify'    =>  undef
    );
    $filetime{$_} = pack( "LL", 0, 0 ) for keys %filetime;

    my $GetFileTime = Win32::API->new(
        'kernel32',
        'GetFileTime',
        [ 'N', 'P', 'P', 'P' ],
        'I'
    );
    $GetFileTime->Call(
        $self->{'HFILE'},
        $filetime{'create'},
        $filetime{'access'},
        $filetime{'modify'}
    );
    $self->{ uc $_ } = $filetime{ $_ } for keys %filetime;

    CloseHandle( $self->{'HFILE'} );

    bless $self, $class;
    return $self;
}


1;


__END__