File Coverage

blib/lib/WebService/YTSearch.pm

Criterion	Covered	Total	%
statement	37	39	94.8
branch	1	2	50.0
condition			n/a
subroutine	11	12	91.6
pod	1	1	100.0
total	50	54	92.5

package WebService::YTSearch;
our $AUTHORITY = 'cpan:GENE';

# ABSTRACT: Search YouTube

our $VERSION = '0.0302';

use Moo;
use strictures 2;
use namespace::clean;

use Carp;
use Mojo::UserAgent;
use Mojo::JSON qw( decode_json );
use Mojo::URL;
use Try::Tiny;


has key => (
    is       => 'ro',
    required => 1,
);


has base => (
    is      => 'rw',
    default => sub { 'https://www.googleapis.com' },
);


has ua => (
    is      => 'rw',
    default => sub { Mojo::UserAgent->new },
);


sub search {
    my ( $self, %args ) = @_;

    my $url = Mojo::URL->new( $self->base )
        ->path('youtube/v3/search')
        ->query(
            %args,
            part => 'snippet',
            key  => $self->key,
        );

    my $tx = $self->ua->get($url);

    my $data = _handle_response($tx);

    return $data;
}

sub _handle_response {
    my ($tx) = @_;

    my $data;

    my $res = $tx->result;

    if ( $res->is_success ) {
        my $body = $res->body;
        try {
            $data = decode_json($body);
        }
        catch {
            croak $body, "\n";
        };
    }
    else {
        croak "Connection error: ", $res->message, "\n";
    }

    return $data;
}

1;

__END__