File Coverage

blib/lib/WebService/TimeAndDateCom/NewYearsCountdown.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch	9	14	64.2
condition			n/a
subroutine	8	8	100.0
pod	1	1	100.0
total	56	61	91.8

package WebService::TimeAndDateCom::NewYearsCountdown;

use Moo;
use Mojo::DOM;
use LWP::UserAgent;
our $VERSION = '1.001';

use constant TIME_AND_DATE_SITE_URL
    => 'http://www.timeanddate.com/counters/multicountdown.html';


has error => ( is => 'rw', init_arg => undef, );
has _ua => (
    is          => 'ro',
    init_arg    => undef,
    default     => sub {
        LWP::UserAgent->new(
            timeout => 30,
            agent => 'Mozilla/5.0 (X11; Ubuntu; Linux i686; '
                .'rv:26.0) Gecko/20100101 Firefox/26.0',
        );
    },
);

sub hny {
    my ( $self, $tz ) = @_;

    my $data = $self->_get_data
        or return;

    if ( $tz ) {
        $tz = uc $tz;
        $tz = 'GMT' if $tz eq 'UTC';

        my ( $tz_data ) = grep $_->{tz} eq $tz, @$data
            or return $self->_set_error('Didn\'t find time zone ' . $tz);

        return $tz_data;
    }

    return $data;
}

sub _get_data {
    my $self = shift;

    my $res = $self->_ua->get( TIME_AND_DATE_SITE_URL );

    return $self->_set_error('Network error: ' . $res->status_line)
        unless $res->is_success;

    my $parsed_data = $self->_parse( $res->content )
        or return; # errored out and the error is already set

    return $parsed_data;
}

sub _parse {
    my ( $self, $content ) = @_;

    my @data;
    eval {
        my $dom = Mojo::DOM->new( $content );
        for my $tr ( $dom->find('table.mpad.tbbox tbody tr')->each ) {
            my %row;
            @row{qw/countries  tz  cities  time_left/}
            = map $_->all_text, $tr->find('td')->each;
            push @data, +{ %row };
        }
    };

    $@ and return $self->_set_error('Parse error: ' . $@);
    return \@data;
}

sub _set_error {
    my ( $self, $error ) = @_;
    $self->error( $error );
    return;
}

'HAPPY NEW YEAR!!!!';

__END__