File Coverage

blib/lib/Wasm/Wasmtime/Module/Imports.pm

Criterion	Covered	Total	%
statement	45	47	95.7
branch	3	4	75.0
condition	1	3	33.3
subroutine	11	14	78.5
pod	0	2	0.0
total	60	70	85.7

package Wasm::Wasmtime::Module::Imports;

use strict;
use warnings;
use 5.008004;
use Carp ();
use Hash::Util ();
use overload
  '%{}' => sub {
    my $self   = shift;
    my $module = $$self;
    $module->{imports};
  },
  '@{}' => sub {
    my $self = shift;
    my $module = $$self;
    my @imports = $module->_imports;
    Internals::SvREADONLY @imports, 1;
    Internals::SvREADONLY $imports[$_], 1 for 0..$#imports;
    \@imports;
  },
  bool => sub { 1 },
  fallback => 1;

# ABSTRACT: Wasmtime module imports class
our $VERSION = '0.22'; # VERSION


sub new
{
  my($class, $module) = @_;

  $module->{imports} ||= do {
    my @imports = $module->_imports;
    my %imports;
    foreach my $export (@imports)
    {
      $imports{$export->name} = $export->type;
    }
    Hash::Util::lock_hash(%imports);
    \%imports;
  };

  bless \$module, $class;
}

sub can
{
  my($self, $name) = @_;
  my $module = $$self;
  exists $module->{imports}->{$name}
    ? sub { $self->$name }
    : $self->SUPER::can($name);
}

sub AUTOLOAD
{
  our $AUTOLOAD;
  my $self = shift;

  my $name = $AUTOLOAD;
  $name=~ s/^.*:://;

  my $module = $$self;
  Carp::croak("no export $name") unless exists $module->{imports}->{$name};
  $module->{imports}->{$name};
}

sub DESTROY
{
  # needed because of AUTOLOAD
}


1;

__END__