File Coverage

blib/lib/Wasm/Wasmtime/Linker.pm

Criterion	Covered	Total	%
statement	36	36	100.0
branch			n/a
condition			n/a
subroutine	13	13	100.0
pod	1	1	100.0
total	50	50	100.0

package Wasm::Wasmtime::Linker;

use strict;
use warnings;
use 5.008004;
use Wasm::Wasmtime::FFI;
use Wasm::Wasmtime::Store;
use Wasm::Wasmtime::Extern;
use Wasm::Wasmtime::Instance;
use Wasm::Wasmtime::WasiInstance;
use Wasm::Wasmtime::Func;
use Wasm::Wasmtime::Trap;
use Ref::Util qw( is_blessed_ref );
use Carp ();

# ABSTRACT: Wasmtime linker class
our $VERSION = '0.22'; # VERSION


$ffi_prefix = 'wasmtime_linker_';
$ffi->load_custom_type('::PtrObject' => 'wasmtime_linker_t' => __PACKAGE__);


$ffi->attach( new => ['wasm_store_t'] => 'wasmtime_linker_t' => sub {
  my($xsub, $class, $store) = @_;
  my $self = $xsub->($store);
  $self->{store} = $store;
  $self;
});


$ffi->attach( allow_shadowing => [ 'wasmtime_linker_t', 'bool' ] => sub {
  my($xsub, $self, $value) = @_;
  $xsub->($self, $value);
  $self;
});


$ffi->attach( define => ['wasmtime_linker_t', 'wasm_byte_vec_t*', 'wasm_byte_vec_t*', 'opaque'] => 'wasmtime_error_t' => sub {
  my $xsub   = shift;
  my $self   = shift;
  my $module = Wasm::Wasmtime::ByteVec->new(shift);
  my $name   = Wasm::Wasmtime::ByteVec->new(shift);
  my $extern = shift;

  # Fix this sillyness when/if ::Extern becomes a base class for extern classes
  if(is_blessed_ref($extern) && (   $extern->isa('Wasm::Wasmtime::Extern')
                                 || $extern->isa('Wasm::Wasmtime::Func')
                                 || $extern->isa('Wasm::Wasmtime::Memory')
                                 || $extern->isa('Wasm::Wasmtime::Global')
                                 || $extern->isa('Wasm::Wasmtime::Table')))
  {
    my $error = $xsub->($self, $module, $name, $extern->{ptr});
    Carp::croak($error->message) if $error;
    return $self;
  }
  else
  {
    Carp::croak("not an extern: $extern");
  }
});


$ffi->attach( define_wasi => ['wasmtime_linker_t', 'wasi_instance_t'] => 'wasmtime_error_t' => sub {
  my($xsub, $self, $wasi) = @_;
  my $error = $xsub->($self, $wasi);
  Carp::croak($error->message) if $error;
  $self;
});


$ffi->attach( define_instance => ['wasmtime_linker_t', 'wasm_byte_vec_t*', 'wasm_instance_t'] => 'wasmtime_error_t' => sub {
  my($xsub, $self, $name, $instance) = @_;
  my $vname = Wasm::Wasmtime::ByteVec->new($name);
  my $error = $xsub->($self, $vname, $instance);
  Carp::croak($error->message) if $error;
  $self;
});


$ffi->attach( instantiate => ['wasmtime_linker_t','wasm_module_t','opaque*','opaque*'] => 'wasmtime_error_t' => sub {
  my($xsub, $self, $module) = @_;
  my $trap;
  my $ptr;
  my $error = $xsub->($self, $module, \$ptr, \$trap);
  Carp::croak($error->message) if $error;
  if($trap)
  {
    $trap = Wasm::Wasmtime::Trap->new($trap);
    die $trap;
  }
  elsif($ptr)
  {
    return Wasm::Wasmtime::Instance->new(
      $module, $self->store, $ptr,
    );
  }
  else
  {
    Carp::croak("unknown instantiate error");
  }
});


$ffi->attach( get_one_by_name => ['wasmtime_linker_t','wasm_byte_vec_t*','wasm_byte_vec_t*','opaque*'] => 'wasmtime_error_t' => sub {
  my($xsub, $self, $module, $name) = @_;
  my $vmodule = Wasm::Wasmtime::ByteVec->new($module);
  my $vname = Wasm::Wasmtime::ByteVec->new($name);
  my $ptr;
  if(my $error = $xsub->($self, $vmodule, $vname, \$ptr))
  {
    Carp::croak($error->message);
  }
  else
  {
    $ptr
      ? $ffi->cast('opaque','wasm_extern_t',$ptr)
      : undef;
  }
});


$ffi->attach( get_default => ['wasmtime_linker_t','wasm_byte_vec_t*','opaque*'] => 'wasmtime_error_t' => sub {
  my($xsub, $self, $name) = @_;
  my $vname = Wasm::Wasmtime::ByteVec->new($name);
  my $ptr;
  if(my $error = $xsub->($self, $vname, \$ptr))
  {
    Carp::croak($error->message);
  }
  else
  {
    return $ptr ? Wasm::Wasmtime::Func->new($ptr, $self) : undef;
  }
});


sub store { shift->{store} }

_generate_destroy();

1;

__END__