File Coverage

blib/lib/Wasm/Wasmtime/FuncType.pm

Criterion	Covered	Total	%
statement	36	36	100.0
branch	6	6	100.0
condition	2	3	66.6
subroutine	10	10	100.0
pod	1	1	100.0
total	55	56	98.2

package Wasm::Wasmtime::FuncType;

use strict;
use warnings;
use 5.008004;
use base qw( Wasm::Wasmtime::ExternType );
use Ref::Util qw( is_arrayref );
use Wasm::Wasmtime::FFI;
use Wasm::Wasmtime::ValType;
use constant is_functype => 1;
use constant kind => 'functype';

# ABSTRACT: Wasmtime function type class
our $VERSION = '0.21'; # VERSION


$ffi_prefix = 'wasm_functype_';
$ffi->load_custom_type('::PtrObject' => 'wasm_functype_t' => __PACKAGE__);


$ffi->attach( new => ['wasm_valtype_vec_t*', 'wasm_valtype_vec_t*'] => 'wasm_functype_t' => sub {
  my $xsub = shift;
  my $class = shift;
  if(is_arrayref $_[0] && is_arrayref $_[1])
  {
    # try not to think too much about all of the maps here
    my($params, $results) = map { my $rec = Wasm::Wasmtime::ValTypeVec->new; $rec->set($_) }
                            map { [map { delete $_->{ptr} } map { Wasm::Wasmtime::ValType->new($_) } @$_] } @_;
    my $self = $xsub->($params, $results);
    return $self;
  }
  else
  {
    my($ptr, $owner) = @_;
    bless {
      ptr   => $ptr,
      owner => $owner,
    }, $class;
  }
});


$ffi->attach( params => ['wasm_functype_t'] => 'wasm_valtype_vec_t*' => sub {
  my($xsub, $self) = @_;
  $xsub->($self)->to_list;
});


$ffi->attach( results => ['wasm_functype_t'] => 'wasm_valtype_vec_t*' => sub {
  my($xsub, $self) = @_;
  $xsub->($self)->to_list;
});


sub to_string
{
  my($self) = @_;
  my @params  = map { $_->to_string } $self->params;
  my @results = map { $_->to_string } $self->results;

  my $string = '';
  $string .= "(param @params)" if @params;
  $string .= ' ' if $string && @results;
  $string .= "(result @results)" if @results;
  $string;
}

__PACKAGE__->_cast(0);
_generate_destroy();

1;

__END__