File Coverage

lib/WWW/Mixi/Scraper.pm

Criterion	Covered	Total	%
statement	24	52	46.1
branch	0	12	0.0
condition	0	3	0.0
subroutine	8	11	72.7
pod	2	2	100.0
total	34	80	42.5

package WWW::Mixi::Scraper;

use strict;
use warnings;

our $VERSION = '0.34';

use String::CamelCase qw( decamelize );
use Module::Find;

use WWW::Mixi::Scraper::Mech;
use WWW::Mixi::Scraper::Utils qw( _uri );

sub new {
  my ($class, %options) = @_;

  my $mode = delete $options{mode};
     $mode = ( $mode && uc $mode eq 'TEXT' ) ? 'TEXT' : 'HTML';

  my $mech = WWW::Mixi::Scraper::Mech->new(%options);

  my $self = bless { mech => $mech, mode => $mode }, $class;

  no strict   'refs';
  no warnings 'redefine';
  foreach my $plugin ( findsubmod 'WWW::Mixi::Scraper::Plugin' ) {
    my ($name) = decamelize($plugin) =~ /(\w+)$/;
    $self->{$name} = $plugin;
    *{"$class\::$name"} = sub {
      my $self = shift;
      my $package = $self->{$name};
      return $package if ref $package;
      eval "require $package" or die $@;
      $self->{$name} = $package->new( mech => $mech, mode => $mode );
    };
  }

  $self;
}

sub parse {
  my ($self, $uri, %options) = @_;

  $uri = _uri($uri) unless ref $uri eq 'URI';

  my $path = $uri->path;
  $path =~ s|^/||;
  $path =~ s|\.pl$||;

  unless ( $self->can($path) ) {
    warn "You don't have a proper plugin to handle $path";
    return;
  }

  foreach my $key ( $uri->query_param ) {
    next if exists $options{$key};
    $options{$key} = $uri->query_param($key);
  }
  $self->$path->parse( %options );
}

1;

__END__