File Coverage

blib/lib/WWW/Google/Cloud/Messaging/Response.pm

Criterion	Covered	Total	%
statement	24	45	53.3
branch	0	2	0.0
condition	0	2	0.0
subroutine	8	16	50.0
pod	3	4	75.0
total	35	69	50.7

package WWW::Google::Cloud::Messaging::Response;

use strict;
use warnings;
use JSON qw(decode_json);

use WWW::Google::Cloud::Messaging::Response::ResultSet;

sub new {
    my ($class, $http_response) = @_;

    my $is_success = $http_response->is_success;
    my $content    = $http_response->content;
    my $reg_ids    = [];

    if ($is_success) {
        $content = decode_json $content;
        $reg_ids = decode_json($http_response->request->content)->{registration_ids};
    }
    else {
        $content = { error => $content };
    }

    bless {
        is_success    => $is_success,
        content       => $content,
        reg_ids       => $reg_ids,
        http_response => $http_response,
    }, $class;
}

sub http_response {
    shift->{http_response};
}

sub is_success {
    shift->{is_success};
}

for my $method (qw{success failure multicast_id canonical_ids error}) {
    no strict 'refs';
    *{$method} = sub {
        use strict;
        shift->{content}{$method};
    };
}

sub results {
    my $self = shift;
    my $results = $self->{content}{results} || return;
    WWW::Google::Cloud::Messaging::Response::ResultSet->new($results, $self->{reg_ids});
}

sub DESTROY  {}
sub AUTOLOAD {
    (my $method = our $AUTOLOAD) =~ s/.*:://;
    no strict 'refs';
    *{$AUTOLOAD} = sub {
        use strict;
        my $self = shift;
        $self->{http_response}->$method(@_);
    };
    goto &$AUTOLOAD;
}

1;
__END__