File Coverage

blib/lib/WWW/Google/Cloud/Messaging.pm

Criterion	Covered	Total	%
statement	41	42	97.6
branch	5	8	62.5
condition	4	6	66.6
subroutine	11	11	100.0
pod	2	2	100.0
total	63	69	91.3

package WWW::Google::Cloud::Messaging;

use strict;
use warnings;
use 5.008_001;

use Carp qw(croak);
use LWP::UserAgent;
use HTTP::Request;
use JSON qw(encode_json);
use Class::Accessor::Lite (
    new => 0,
    rw  => [qw/ua api_url api_key/],
);

use WWW::Google::Cloud::Messaging::Response;

our $VERSION = '0.04';

our $API_URL = 'https://android.googleapis.com/gcm/send';

sub new {
    my ($class, %args) = @_;
    croak 'Usage: WWW::Google::Cloud::Messaging->new(api_key => $api_key)' unless defined $args{api_key};

    $args{ua}      ||= LWP::UserAgent->new(agent => __PACKAGE__.'/'.$VERSION);
    $args{api_url} ||= $API_URL;

    bless { %args }, $class;
}

sub send {
    my ($self, $payload) = @_;
    croak 'Usage: $gcm->send(\%payload)' unless ref $payload;

    if (exists $payload->{delay_while_idle}) {
        $payload->{delay_while_idle} = $payload->{delay_while_idle} ? JSON::true : JSON::false;
    }

    my $req = HTTP::Request->new(POST => $self->api_url);
    $req->header(Authorization  => 'key='.$self->api_key);
    $req->header('Content-Type' => 'application/json; charset=UTF-8');
    $req->content(encode_json $payload);

    my $res = $self->ua->request($req);
    return WWW::Google::Cloud::Messaging::Response->new($res);
}

1;
__END__