File Coverage

blib/lib/WWW/Bugzilla/BugTree.pm

Criterion	Covered	Total	%
statement	14	37	37.8
branch	0	8	0.0
condition			n/a
subroutine	5	7	71.4
pod	2	2	100.0
total	21	54	38.8

package WWW::Bugzilla::BugTree;

use strict;
use warnings;
use Ref::Util qw( is_arrayref );
use 5.012;
use Moo;

# ABSTRACT: Fetch a tree of bugzilla bugs blocking a bug
our $VERSION = '0.08'; # VERSION


has ua => (
  is      => 'ro',
  lazy    => 1,
  default => sub {
    require LWP::UserAgent;
    my $ua = LWP::UserAgent->new;
    $ua->env_proxy;
    $ua;
  },
);


my $default_url = $ENV{BUG_TREE_URL} // "https://landfill.bugzilla.org/bugzilla-4.2-branch";

has url => (
  is      => 'ro',
  lazy    => 1,
  default => sub {
    require URI;
    URI->new($default_url);
  },
  coerce  => sub {
    ref $_[0] ? $_[0] : do { require URI; URI->new($_[0] // $default_url) },
  },
);

has _cache => (
  is       => 'ro',
  default  => sub { { } },
  init_arg => undef,
);


sub fetch
{
  my($self, $bug_id) = @_;

  return $self->_cache->{$bug_id}
    if exists $self->_cache->{$bug_id};

  my $url = $self->url->clone;
  $url->path((do { my $path = $url->path; $path =~ s{/$}{}; $path }) . "/show_bug.cgi");
  $url->query_form(
    id    => $bug_id,
    ctype => 'xml',
  );

  my $res = $self->ua->get($url);

  die $url . " " . $res->status_line
    unless $res->is_success;

  require WWW::Bugzilla::BugTree::Bug;
  my $b = WWW::Bugzilla::BugTree::Bug->new(
    url => $url,
    res => $res,
    id  => $bug_id,
  );

  $self->_cache->{$bug_id} = $b;

  my $dependson = $b->as_hashref->{bug}->{dependson};
  $dependson = [] unless defined $dependson;
  $dependson = [ $dependson ]
    unless is_arrayref $dependson;

  @{ $b->children } = map { $self->fetch($_) } sort @$dependson;

  $b;
}


sub clear_cache
{
  my($self) = @_;
  %{ $self->_cache } = ();
}

1;

__END__