File Coverage

blib/lib/WQS/SPARQL/Query/Select.pm

Criterion	Covered	Total	%
statement	45	46	97.8
branch	11	12	91.6
condition			n/a
subroutine	7	7	100.0
pod	2	2	100.0
total	65	67	97.0

package WQS::SPARQL::Query::Select;

use strict;
use warnings;

use Class::Utils qw(set_params);
use Error::Pure qw(err);

sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Process parameters.
	set_params($self, @params);

	return $self;
}

sub select_value {
	my ($self, $property_pairs_hr, $filter_ar) = @_;

	my %sort;
	foreach my $property (keys %{$property_pairs_hr}) {
		if ($property !~ m/^P(\d+)(\/P\d+\*?)?$/ms) {
			err "Bad property '$property'.";
		}
		$sort{$property} = $1;
	}

	my $sparql = "SELECT ?item WHERE {\n";
	foreach my $property (sort { $sort{$a} <=> $sort{$b} } keys %{$property_pairs_hr}) {
		my $property_wdt = $self->_property($property);

		my $value = $property_pairs_hr->{$property};
		if ($value =~ m/^Q\d+$/ms) {
			$value = "wd:$value";
		} elsif ($value =~ m/^\?/ms) {
			# same
		} elsif ($value =~ m/^(.*?)(@\w\w)$/ms) {
			$value = "'$1'$2";
		} else {
			$value = "'$value'";
		}

		$sparql .= "  ?item $property_wdt $value.\n"
	}
	foreach my $filter_item_ar (@{$filter_ar}) {
		$sparql .= '  FILTER('.$filter_item_ar->[0].' '.$filter_item_ar->[1].' '.$filter_item_ar->[2].')'."\n";
	}
	$sparql .= "}\n";

	return $sparql;
}

sub _property {
	my ($self, $property_key) = @_;

	my $property_wdt;
	if ($property_key =~ m/^P\d+$/ms) {
		$property_wdt = 'wdt:'.$property_key;
	} elsif ($property_key =~ m/^(P\d+)\/(P\d+\*?)$/ms) {
		$property_wdt = 'wdt:'.$1.'/wdt:'.$2;
	} else {
		err "Property doesn't supported.",
			'property_key', $property_key,
		;
	}

	return $property_wdt;
}

1;

__END__