File Coverage

blib/lib/Video/Generator.pm

Criterion	Covered	Total	%
statement	63	83	75.9
branch	4	20	20.0
condition			n/a
subroutine	14	15	93.3
pod	2	2	100.0
total	83	120	69.1

package Video::Generator;

use strict;
use warnings;

use Class::Utils qw(set_params);
use Error::Pure qw(err);
use FFmpeg::Command;
use File::Path qw(rmtree);
use File::Spec::Functions qw(catfile);
use File::Temp qw(tempdir);
use IO::CaptureOutput qw(capture_exec);
use Image::Random;
use Readonly;
use Video::Delay::Const;
use Video::Pattern;

# Constants.
Readonly::Scalar our $SPACE => q{ };

our $VERSION = 0.09;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Delay generator.
	$self->{'delay_generator'} = undef;

	# Duration.
	$self->{'duration'} = 10000;

	# Frames per second.
	$self->{'fps'} = 60;

	# FFmpeg pixel format.
	$self->{'ffmpeg_pixel_format'} = undef;

	# FFmpeg video codec.
	$self->{'ffmpeg_video_codec'} = undef;

	# Image generator.
	$self->{'image_generator'} = undef;

	# Image type.
	$self->{'image_type'} = 'bmp';

	# Temporary dir.
	$self->{'temp_dir'} = undef;

	# Verbose mode.
	$self->{'verbose'} = 0;

	# Video pattern generator.
	$self->{'video_pattern'} = undef;

	# Sizes.
	$self->{'height'} = 1080;
	$self->{'width'} = 1920;

	# Process params.
	set_params($self, @params);

	# Temporary directory.
	if (! defined $self->{'temp_dir'}) {
		$self->{'temp_dir'} = tempdir();
	}

	# Image generator.
	if (! defined $self->{'image_generator'}) {
		$self->{'image_generator'} = Image::Random->new(
			'height' => $self->{'height'},
			'type' => $self->{'image_type'},
			'width' => $self->{'width'},
		);
	}

	# Delay generator.
	if (! defined $self->{'delay_generator'}) {
		$self->{'delay_generator'} = Video::Delay::Const->new(
			'const' => 1000,
		);
	}

	# Video pattern generator.
	if (! defined $self->{'video_pattern'}) {
		$self->{'video_pattern'} = Video::Pattern->new(
			'delay_generator' => $self->{'delay_generator'},
			'duration' => $self->{'duration'},
			'fps' => $self->{'fps'},
			'image_generator' => $self->{'image_generator'},
		);
	}

	# Object.
	return $self;
}

# Create random video.
sub create {
	my ($self, $out_path) = @_;

	# Create images.
	$self->{'video_pattern'}->create($self->{'temp_dir'});
	if ($self->{'verbose'}) {
		print "Video pattern generator created images for video in ".
			"temporary directory.\n";
	}

	# Create video.
	my $ffmpeg = FFmpeg::Command->new;
	my $images_path = catfile($self->{'temp_dir'},
		'%03d.'.$self->{'image_type'});
	my @command_options = ('-loglevel', 'error', '-r', $self->{'fps'},
		'-i', $images_path,
		$self->{'ffmpeg_video_codec'}
			? ('-c:v', $self->{'ffmpeg_video_codec'})
			: (),
		$self->{'ffmpeg_pixel_format'}
			? ('-pix_fmt', $self->{'ffmpeg_pixel_format'})
			:(),
		'-pix_fmt', 'yuv420p',
		$out_path);
	$ffmpeg->options(@command_options);
	$ffmpeg->exec;
	if ($ffmpeg->stderr) {
		my @stderr = split m/\n/ms, $ffmpeg->stderr;
		my $command = join $SPACE, @command_options;
		err "Error with command 'ffmpeg $command'.",
			map { ('STDERR', $_) } @stderr;
	}
	if ($self->{'verbose'}) {
		print "Created video file.\n";
	}

	# Remove temporary directory.
	rmtree $self->{'temp_dir'};
	if ($self->{'verbose'}) {
		print "Removed temporary directory.\n";
	}

	return;
}

1;

__END__