File Coverage

blib/lib/Versioning/Scheme/Python.pm

Criterion	Covered	Total	%
statement	67	84	79.7
branch	23	44	52.2
condition	15	19	78.9
subroutine	12	12	100.0
pod	5	5	100.0
total	122	164	74.3

package Versioning::Scheme::Python;

our $DATE = '2018-11-18'; # DATE
our $VERSION = '0.001'; # VERSION

use 5.010001;
use strict;
use warnings;

use Role::Tiny;
use Role::Tiny::With;
with 'Role::Versioning::Scheme';
use PerlX::Maybe;
use Python::Version;

sub is_valid_version {
    my ($self, $v) = @_;
    eval { Python::Version->parse($v) };
    $@ ? 0:1;
}

sub parse_version {
    my ($self, $v) = @_;

    my $vp;
    eval { $vp = Python::Version->parse($v) };
    return undef if $@;
    +{
        maybe epoch          => $vp->{_epoch},
        maybe base           => $vp->{_base_version},
        maybe prerelease     => $vp->{_prerelease},
        maybe postrelease    => $vp->{_postrelease},
        maybe devrelease     => $vp->{_devrelease},
        maybe local          => $vp->{_local_version},
    };
}

sub normalize_version {
    my ($self, $v) = @_;
    Python::Version->parse($v)->normal;
}

sub cmp_version {
    my ($self, $v1, $v2) = @_;

    Python::Version->parse($v1) <=> Python::Version->parse($v2);
}

sub bump_version {
    my ($self, $v, $opts) = @_;
    $opts //= {};
    $opts->{num} //= 1;
    $opts->{part} //= -1;
    $opts->{reset_smaller} //= 1;

    my $vp = Python::Version->parse($v);
    die "Invalid 'num', must be non-zero" unless $opts->{num} != 0;

    if ($opts->{part} =~ /\A-?\d+\z/) {
        die "Invalid 'part', must not be smaller than -".@{$vp->{_base_version}}
            if $opts->{part} < -@{ $vp->{_base_version} };
        die "Invalid 'part', must not be larger than ".$#{$vp->{_base_version}}
            if $opts->{part} > $#{$vp->{_base_version}};

        my $idx = $opts->{part}; $idx = @{$vp->{_base_version}} + $idx if $idx < 0;
        # for now, we do not allow decreasing that overflow to the next more
        # significant part
        die "Cannot decrease version, would result in a negative part"
            if $vp->{_base_version}[$idx] + $opts->{num} < 0;
        my $i = $idx;
        my $left = $opts->{num};
        while (1) {
            if ($i == 0 || $vp->{_base_version}[$i]+$left < 1000) {
                $vp->{_base_version}[$i] += $left;
                $left = 0;
                last;
            } else {
                my $tmp = $vp->{_base_version}[$i] + $left;
                $vp->{_base_version}[$i] = $tmp % 1000;
                $left = int($tmp / 1000);
                $i--;
                next;
            }
        }
        if ($opts->{reset_smaller} && $opts->{num} > 0) {
            $idx = @{$vp->{_base_version}} + $idx if $idx < 0;
            for my $i ($idx+1 .. $#{$vp->{_base_version}}) {
                $vp->{_base_version}[$i] = 0;
            }
        }
    } elsif ($opts->{part} =~ /\A(a|b|rc)\z/) {
        die "Can't bump version: no $opts->{part} part"
            unless $vp->{_prerelease} && $vp->{_prerelease}[0] eq $opts->{part};
        die "Cannot decrease version, would result in a negative $opts->{part} part"
            if $vp->{_prerelease}[1] + $opts->{num} < 0;
        $vp->{_prerelease}[1] += $opts->{num};
    } elsif ($opts->{part} eq 'post') {
        die "Can't bump version: no $opts->{part} part"
            unless $vp->{_postrelease};
        die "Cannot decrease version, would result in a negative $opts->{part} part"
            if $vp->{_postrelease}[1] + $opts->{num} < 0;
        $vp->{_postrelease}[1] += $opts->{num};
    } elsif ($opts->{part} eq 'dev') {
        die "Can't bump version: no $opts->{part} part"
            unless $vp->{_devrelease};
        die "Cannot decrease version, would result in a negative $opts->{part} part"
            if $vp->{_devrelease}[1] + $opts->{num} < 0;
        $vp->{_devrelease}[1] += $opts->{num};
    } elsif ($opts->{part} eq 'epoch') {
        $vp->{_epoch} //= 0;
        die "Cannot decrease version, would result in a negative $opts->{part} part"
            if $vp->{_epoch} + $opts->{num} < 0;
        $vp->{_epoch} += $opts->{num};
    } else {
        die "Invalid part '$opts->{part}'";
    }
    $vp->normal;
}

1;
# ABSTRACT: Python (PEP 440) version numbering

__END__