File Coverage

blib/lib/Tie/ScalarFile.pm

Criterion	Covered	Total	%
statement	12	36	33.3
branch	0	18	0.0
condition	0	3	0.0
subroutine	4	9	44.4
pod	1	1	100.0
total	17	67	25.3

package Tie::ScalarFile;

use Carp;
use strict;
use warnings;
use warnings::register;

our $VERSION = "1.12";

my $count = 0;

sub TIESCALAR {
   my $class   = shift;
   my $filename = shift;
   my $fh;

   if (open $fh, "<", $filename or
       open $fh, ">", $filename)
   {
          close $fh;
          $count++;
          return bless \$filename, $class;
   }
   carp "Can't tie $filename: $!" if warnings::enabled();
   return;
}

sub FETCH {
   my $self = shift;
   confess "I am not a class method" unless ref $self;
   return unless open my $fh, $$self;
   read ($fh, my $value, -s $fh);
   return $value;
}

sub STORE {
   my ($self, $value) = @_;
   ref $self                  or confess "not a class method";
   open my $fh, ">", $self    or croak   "can't clobber $$self: $!";
   syswrite ($fh, $value) == length $value
                              or croak "can't write to $$self: $!";
   close $fh                  or croak "can't close $$self: $!";
   return $value;
}

sub DESTROY {
   my $self = shift;
   confess "wrong type" unless ref $self;
   $count--;
}

sub count { $count }


1;
__END__